Excel ist in der Lage mit ein paar Formeln Angaben über die aktuelle Datei auszugeben. In diesem Artikel wir erklärt, wie man mit Excel ausgeben kann, wo eine Datei gespeichert ist, wie das aktuelle Datenblatt heißt, oder noch viele weitere Optionen.

Selbstverständlich kann man den Dateipfad des Dokuments auch ganz normal herausbekommen, hat man das Dokument aber schon geöffnet, so kann man auch einfach die folgenden Formeln eingeben um teilweise auch Ergebnisse zu erhalten, die auf „normalem“ Weg sonst nicht erreichbar sind.

Beginn:

Hier möchte ich ihnen einfach nur zeigen, in welchem Ordner meine Datei liegt und unter welchem Dateipfad sie zu finden ist. Mit dem Bild hier können Sie anschließend immer vergleichen, ob die Formeln auch richtig funktionieren. Bevor Sie mit den unten aufgeführten Schritten weiter machen, sollten Sie zuerst einmal Excel öffnen und das Dokument abspeichern, da sonst natürlich der Speicherort nicht ausgelesen werden kann.

(Zur Darstellung in Originalgröße Abbildungen anklicken)
01-excel-formeln-angaben-ueber-die-datei-ordner-470.png?nocache=1308269034956

Dateipfad inklusive Datenblattname auslesen:

Dies ist zum Beispiel eine Funktion, die Sie so nicht bekommen würden, wenn Sie einfach in den Ordner gehen, indem die Datei liegt. Bei dieser Formel wird nämlich auch noch der Name des aktuellen Datenblatts ausgegeben. Möchten Sie dies erreichen, so schreiben Sie in irgendeine beliebige Zelle folgende Formel:

=ZELLE("Dateiname";$A$1)

Der Parameter A1 soll Sie nicht weiter stören, er hat nichts damit zu tun, in welche Zelle Sie die Formel schreiben. Ausgegeben wird nun der Dateipfad mit dem Namen des aktuellen Datenblatts. Dieser ist in den eckigen Klammern eingetragen.

02-excel-formeln-angaben-ueber-die-datei-vollstaendiger-pfad-470.png?nocache=1308269053620

Dateipfad ohne Datenblattname auslesen:

Ist es für Sie irrelevant, in welchem Datenblatt Sie sich befinden, da Sie nur eines benutzen, oder die anderen gelöscht haben, so reicht ihnen schon die folgende Formel aus. Sie macht das gleiche wie die Formel oben, jedoch wird hier der Datenblattname weggelassen. Um den Dateipfad zu bekommen schreiben Sie nun wieder in ein frei wählbares Feld folgende Formel:

=WECHSELN(LINKS(ZELLE("Dateiname";$A$1);-1+FINDEN("]";ZELLE("Dateiname";$A$1)));"[";"")

Die Formel hat auch die gleiche Arbeitsweise, wie im Beispiel zuvor, da Excel den Dateinamen nur in diesem Stil ausgeben kann, es wurde aber so eingestellt, dass der Text nach der geschlossenen eckigen Klammer gelöscht wird.

03-excel-formeln-angaben-ueber-die-datei-pfad-ohne-datenblatt-470.png?nocache=1308269072899

Verzeichnispfad auslesen:

Eine weitere Sache, die ausgegeben werde kann ist der Verzeichnispfad. Dieser ist einfach der komplette Dateipfad, aber ohne den Dateinamen. Die Formel hierfür lautet deshalb:

=LINKS(ZELLE("Dateiname";$A$1);FINDEN("[";ZELLE("Dateiname";$A$1))-2)

Hierbei wird wieder die Vorgehensweise von Beispiel 1 benutzt, jedoch wird alles ab der ersten eckigen Klammer gelöscht. Übrig bleibt also nur noch der Verzeichnispfad, also der Pfad zu dem Ordner, in dem sich die Excel Datei befindet.

04-excel-formeln-angaben-ueber-die-datei-ordner-pfad-470.png?nocache=1308269093979

Ordnernamen auslesen:

Außerdem ist es mit einer Formel auch möglich nur den Namen des Ordners auszulesen. Wie Sie sich schon denken können, basiert dies auch auf der Formel von Beispiel 1. Möchten Sie genau das erreichen, so schreiben Sie nun in ein beliebiges  Feld:

=TEIL(ZELLE("Dateiname";$A$1);FINDEN("#";WECHSELN(ZELLE("Dateiname";$A$1);"\";"#";LÄNGE(ZELLE("Dateiname";$A$1))-LÄNGE(WECHSELN(ZELLE("Dateiname";$A$1);"\";))-1))+1;FINDEN("\";TEIL(ZELLE("dateiname";$A$1);FINDEN("#";WECHSELN(ZELLE("Dateiname";$A$1);"\";"#";LÄNGE(ZELLE("Dateiname";$A$1))-LÄNGE(WECHSELN(ZELLE("Dateiname";$A$1);"\";))-1))+1;90))-1)

Haben Sie diese Formel eingeben und bestätigt, erscheint in der Zelle der Name des Ordners, in meinem Fall liegt die Datei im Ordner „Excel“, daher wird das auch ausgegeben.

05-excel-formeln-angaben-ueber-die-datei-ordnername-470.png?nocache=1308269114308

Dateinamen mit Endung auslesen:

Möchten Sie den Namen der Datei inklusive der Dateiendung erfahren, so gibt es dafür selbstverständlich auch eine Formel. Nachdem dabei wieder einmal der komplette Dateipfad ausgelesen wird, wird nun alles bis auf den Text zwischen der geöffneten spitzen Klammer und der geschlossenen spitzen Klammer weggeschnitten. Übrig bleibt also der Dateiname mit der Endung. Die Formel dafür lautet:

=TEIL(ZELLE("Dateiname";$A$1);FINDEN("[";ZELLE("Dateiname";$A$1))+1;FINDEN("]";ZELLE("Dateiname";$A$1))-FINDEN("[";ZELLE("Dateiname";$A$1))-1)

06-excel-formeln-angaben-ueber-die-datei-dateiname-470.png?nocache=1308269153179

Dateinamen ohne Endung auslesen:

Wenn Sie an den Dateinamen ohne die Excel Endung gelangen möchten, so müssen Sie nun folgendes tun. Die Formel basiert auf der Formel aus dem Beispiel zuvor. Dabei interessiert uns nun die letzte Ziffer in der Formel, also die 1. Diese müssen Sie ändern. Um zu wissen, was Sie dort eintragen möchten, müssen Sie wissen in welchem Format Sie die Datei zu Beginn gespeichert haben. War es das neue „xlsx“ Format, so ersetzen Sie die „1“ durch eine „6“. Die Formel sähe dann so aus:

=TEIL(ZELLE("Dateiname";$A$1);FINDEN("[";ZELLE("Dateiname";$A$1))+1;FINDEN("]";ZELLE("Dateiname";$A$1))-FINDEN("[";ZELLE("Dateiname";$A$1))-6)

Ist die Datei aber im Format „xls“, so ersetzen Sie die „1“ durch eine „5“. Die Formel würde dann wie folgt lauten:

=TEIL(ZELLE("Dateiname";$A$1);FINDEN("[";ZELLE("Dateiname";$A$1))+1;FINDEN("]";ZELLE("Dateiname";$A$1))-FINDEN("[";ZELLE("Dateiname";$A$1))-5)

07-excel-formeln-angaben-ueber-die-datei-dateiname-ohne-endung-470.png?nocache=1308269189823

Name des Datenblatts auslesen:

Die letze Möglichkeit die Sie haben, etwas bei dem Dateinamen auszulesen, ist der Name des Datenblatts. Im Dokument selbst finden Sie diesen am linken unteren Rand des Zellbereiches. Um diesen zu bekommen benötigen Sie folgende Formel:

=TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+1;31)

Auch hier wird wieder mal auf Beispiel 1 aufgegriffen. Jedoch wird hier nur der Teil hinter der geschlossenen spitzen Klammer angezeigt.

08-excel-formeln-angaben-ueber-die-datei-datenblattname-470.png?nocache=1308269212837

Nun haben Sie einige Möglichkeiten kennengelernt, den Dateipfad einer Excel Datei auszugeben. Manche Informationen bekommt man auch nur, indem die Wiedergabe in der Datei erfolgt und nicht mit einem Blick in den Ordner.
In den Formeln finden Sie immer wieder den Begriff „Dateiname“. Möchten Sie, dass die Formeln auch an Rechnern funktionieren, die kein deutsches Betriebssystem aufgespielt haben, so ersetzen Sie „Dateiname“ einfach durch „Filename“.