Excel Formeln – Buchstaben von rechts suchen

Möchten Sie in Excel einen Buchstaben in einem Textfeld suchen, so geht das mit FINDEN oder SUCHEN. Möchten Sie aber dass der letze Buchstabe gefunden wird, so wird das schon schwieriger. Hier wird ihnen erklärt, wie auch das in Zukunft kein Problem mehr sein wird.

FINDEN und SUCHEN dienen in Excel dazu einen Buchstaben in einer Zelle zu finden. Jedoch beginnt die Suche immer von Anfang an, also von links nach rechts. Möchte man nun an den letzten Buchstaben herankommen, so gibt es dafür zwar keine eigene Funktion, aber mit den weiter unten aufgeführten Funktionen wird auch das kein Problem.

Letzen Buchstaben mithilfe einer Matrixformel (Array-Formel) suchen:

Von rechts an zählen:

Für dieses Beispiel habe ich in die Zelle A1 den Text „Ein Text mit vielen „E“-s“ geschrieben. In B1 erfolgt nun die Berechnung der Lage des letzen gesuchten Buchstabens von rechts aus gesehen. Der gesuchte Buchstabe ist ein „e“. Das letzte „e“ ist das in den Anführungszeichen. Von rechts aus gesehen ist dies 4 Zeichen vom Rand entfernt. Um auf die Ausgabe „4“ zu kommen, müssen Sie in die Zelle B1 nun folgende Formel eingeben (mit dem „e“ durch ihren Buchstaben ersetzt):

=VERGLEICH(„e“;LINKS(RECHTS(A1;SPALTE(1:1));1);0)

Diese Formel dürfen Sie aber noch nicht so bestätigen, da sonst ein falsches Ergebnis angezeigt wird. Klicken sie bitte mit der Maus erst noch oben in die Eingabezeile. Jetzt drücken Sie anstatt Enter bitte STRG+SHIFT+Enter gleichzeitig. Dies ist das Zeichen, dass Sie eine Matrixformel eingeben. Haben Sie alle richtig gemacht, erscheinen nun oben in der Zeile mit der Formel geschweifte Klammern ( { } ) am Anfang und am Ende. Die Formel sieht also so aus:

{=VERGLEICH(„e“;LINKS(RECHTS(A1;SPALTE(1:1));1);0)}

(Zur Darstellung in Originalgröße Abbildungen anklicken)

Von links an zählen:
Möchten Sie nun, dass der letze Buchstabe nicht von rechts an, sondern von links an gezählt wird, so muss natürlich auch die Formel verändert werden. Sie lautet diesmal („e“ ersetzen):

=MAX((TEIL(A1;SPALTE(1:1);1)=“e“)*SPALTE(1:1))

Da auch dies wieder eine Matrixformel oder Array-Formel ist, müssen Sie die Eingabe wieder mit STRG+SHIFT+Enter tätigen. Die vollständige Matrixformel lautet also:

{=MAX((TEIL(A1;SPALTE(1:1);1)=“e“)*SPALTE(1:1))}

Letzen Buchstaben ohne eine Matrixformel (Array-Formel) suchen:

Von rechts an zählen:

Die oben aufgeführten Formeln kann man aber auch durch ganz normale Formeln ersetzen. Möchten Sie den letzen Buchstaben wieder von rechts an zählen, so schreiben Sie als neue Formel:

=LÄNGE(A1)+1-FINDEN(„#“;WECHSELN(A1;“e“;“#“;LÄNGE(A1)-LÄNGE(WECHSELN(A1;“e“;““))))

Dies hat nun fast die gleiche Arbeitsweise, wie die Matrixformel. Jedoch ist bei dieser Formel noch anzumerken, dass der zu ersetzende Buchstabe entweder groß oder klein geschrieben ist. Bei der Matrixformel hat das noch nicht gestört, hier aber wird beispielsweise zwischen „e“ und „E“ ein Unterschied gemacht. Das „e“ in der Formel müssen Sie natürlich wieder durch den gewünschten Suchbuchstaben ersetzen.

Von links an zählen:

Die Formel für das Zählen von der linken Seite an, sieht ähnlich aus wie die im Beispiel zuvor. Der einzige Unterschied besteht darin, dass diesmal der Anfang „LÄNGE(A1)+1-“ entfernt wurde. Die Formel, um von der linken Seite mit dem Zählen zu beginnen lautet also:

=FINDEN(„#“;WECHSELN(A1;“r“;“#“;LÄNGE(A1)-LÄNGE(WECHSELN(A1;“r“;““))))

Mehrere Zeichen ohne Matrixformel (Array-Formel) suchen:

Von rechts an zählen:

Möchten Sie nicht nur ein Zeichen suchen sondern beispielsweise ein Wort, so bekommen Sie mit der Formel von oben Probleme. Möchten Sie es dennoch tun, so benötigen Sie folgende Formel, wenn die Suche von rechts beginnen soll:

= LÄNGE(A1)+1-FINDEN(„#“;WECHSELN(A1;“Text“;“#“;LÄNGE(A1)-(LÄNGE(“Text“)-1)*(LÄNGE(A1)-LÄNGE(WECHSELN(A1;“Text“;““)))/LÄNGE(“Text“)-LÄNGE(WECHSELN(A1;“Text“;““))))

„Text“ ersetzen Sie hierbei selbstverständlich durch den zu suchenden Text in der Zelle. Dieser muss natürlich auch in Anführungszeichen stehen. Ausgegeben wird nun die Stelle des ersten Buchstabens des zu suchenden Textes. Obwohl ja nach dem Wort „Text“ gesucht wird, wird die Stelle des großen „T“-s ausgegeben, obwohl das kleine „t“ eigentlich näher am rechten Rand wäre.

Von links an zählen:

Wie Sie sich schon denken können, kann man natürlich auch vom linken Rand aus zählen. Wie schon bei der Suche nach einem Buchstaben ohne Matrixformel, sehen sie sich beide ähnlich und unterscheiden sich wieder nur durch den Anfang. Um von links zu zählen, muss nun

=FINDEN(„#“;WECHSELN(A1;“Text“;“#“;LÄNGE(A1)-(LÄNGE(“Text“)-1)*(LÄNGE(A1)-LÄNGE(WECHSELN(A1;“Text“;““)))/LÄNGE(“Text“)-LÄNGE(WECHSELN(A1;“Text“;““))))

schreiben. Der Anfang „LÄNGE(A1)+1-“ wird also auch hier wieder weggelassen.

Jetzt wissen Sie, wie es möglich ist auch den letzen Buchstaben einer Zelle zu suchen und nicht nur den ersten. Zur Auswahl stehen dabei einmal die Verwendung einer Matrixformel, oder der ganz normalen Formeln in Excel.