Du bist hier::--Excel Formeln – Häufigstes Zeichen ausgeben

Excel Formeln – Häufigstes Zeichen ausgeben

Selbstverständlich kann man in Excel neben Zahlen auch Text oder Strings schreiben. Möchte man nun wissen, welches das häufigste Zeichen in einem String ist, so benötigt man dafür eine extra Formel. Hier werde ich ihnen zeigen, wie das funktioniert.

Excel ist in der Lage vieles mit Texten bzw. Zahlen zu machen. Das häufigste darin auftretende Zeichen herauszufinden ist aber nicht so einfach. Hier werden Sie sehen, wie man das mit wenigen Formeln aber trotzdem hinbekommt.

Beginn:

Zu aller erst müssen sie natürlich einen Text eingeben der untersucht werden soll. Schreiben Sie dazu nun in Zelle A1 den Inhalt hinein, der auf das häufigste Zeichen untersucht werden soll. Neben Text kann hier selbstverständlich auch eine Zahl stehen.

Hilfszelle:

Um nun an das häufigste Zeichen und seine Anzahl zu kommen benötigen Sie eine Hilfszelle. Dafür benutzen sie am besten A2. In dieser Zelle wird nachdem die Formel eingegeben wurde angezeigt, wie viele Zeichen der Inhalt der Zelle A1 hat, wenn man das am häufig auftretendste Zeichen nicht mitzählt. Um an diesen Wert zu kommen müssen Sie folgende Matrixformel in die Zelle eintragen:

=MIN(LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);)))

Wie gesagt, ist dies eine Matrixformel. Das bedeutet, dass die Formel nicht einfach mit einem Druck der Enter Taste schon richtig ausgeführt wird. Um an den korrekten Ausgabewert zu kommen, müssen Sie nun oben in die Bearbeitungszeile der Formel gehen. Haben sie das getan, so drücken Sie nun STRG+SHIFT+Enter. Anschließend wird in der Zelle A2 der richtige Wert angezeigt. Da eine Matrixformel nicht wie oben aufgebaut ist, sondern von geschweiften Klammern ( {} ) eingerahmt wird, verändert sich die Formel wie folgt:

{=MIN(LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);)))}

Anmerkung: Ist der Inhalt von Zelle A1 länger als 99 Zeichen, so ändern Sie bitte den Wert „99“ in der Formel auf ihren Wert ab (einfach grob schätzen, z.B. 200)

(Zur Darstellung in Originalgröße Abbildungen anklicken)
01-excel-formel-haeufigstes-zeichen-laenge-470.png?nocache=1308578267436

Häufigstes Zeichen:

Jetzt kann man anzeigen, welches Zeichen am häufigsten in der Zelle A1 auftritt. Schreiben Sie dazu nun in irgendeine freie Zelle in ihrem Datenblatt folgende Formel:

=TEIL(A1;VERGLEICH(A2;LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);));0);1)

Da diese wieder eine Matrixformel ist, müssen Sie wieder oben in die Bearbeitungszeile gehen und anschließend STRG+SHIFT+Enter drücken. Anschließend wird in der Zelle nun der richtige Wert erscheinen. In meinem Fall war das der Buchstabe „s“. Die Formel ändert sich außerdem zu folgender ab:

{=TEIL(A1;VERGLEICH(A2;LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);));0);1)}

Anmerkung: Auch hier müssen Sie wieder schauen, ob der String in Zelle A1 nicht länger als 99 Zeichen ist.

02-excel-formel-haeufigstes-zeichen-zeichen-470.png?nocache=1308578299650

Anzahl des häufigsten Zeichens:

Nun können Sie auch angezeigt bekommen, wie oft dieses Zeichen in A1 vorkommt. Dazu benötigen sie folgende sehr einfache Formel:

=LÄNGE(A1)-A2

Die Formel hier liest einfach die Länge des Zellinhalts von A1 aus und zieht davon den Wert unserer Hilfszelle A2 ab. Als Ergebnis bekommen Sie dann die Anzahl des am häufigsten verwendeten Zeichens. In meinem Fall war das „3“.

03-excel-formel-haeufigstes-zeichen-anzahl-470.png?nocache=1308578321708

Häufigstes Zeichen (ohne Hilfszelle):

Wie fast immer kann man eine Hilfszelle auch vermeiden. So auch in diesem Fall. Zelle A2 können Sie jetzt also löschen. Wenn A2 aber keinen Wert mehr liefert, so funktionieren auch die anderen Formeln nicht mehr. Deshalb benötigen diese neue Formeln. Die Formel, die berechnet, welches das häufigste Zeichen ist lautet nun so:

=TEIL(A1;VERGLEICH(MIN(LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);)));LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);));0);1)

Auch das ist eine Matrixformel,  deshalb gehen Sie wieder in die Bearbeitungszeile und drücken anschließend STRG+SHIFT+Enter. Die Formel im „Matrixstil“ sieht also wieder so aus:

{=TEIL(A1;VERGLEICH(MIN(LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);)));LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);));0);1)}

Haben Sie alles richtig gemacht, so erscheint in dieser Zelle der selbe Wert wie zuvor auch, bei mir also immer noch „s“.

04-excel-formel-haeufigstes-zeichen-zeichen-ohne-a2-470.png?nocache=1308578342354

Anzahl des häufigsten Zeichens (ohne Hilfszelle):

Da die Formel, die auch zur Berechnung der Anzahl des häufigsten Zeichens dient, quasi zur Hälfte aus der Hilfszelle A2 besteht, muss natürlich auch diese verändert werden. Die neue Berechnungsformel, welche auch eine Matrixformel ist, sieht so aus:

=LÄNGE(A1)-MIN(LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);)))

Nachdem Sie die Formel eingegeben haben, klicken Sie nun also wieder oben in die Bearbeitungszeile und drücken Sie danach STRG+SHIFT+Enter. Die Formel sieht umgewandelt dann wieder so aus:

{=LÄNGE(A1)-MIN(LÄNGE(WECHSELN(A1;TEIL(A1;ZEILE(1:99);1);)))}

 Anschließend erscheint in der Zelle der Wert, welcher natürlich dem von davor entspricht, wenn ihnen kein Fehler unterlaufen ist. In meinem Fall war es also immer noch die „3“.

05-excel-formel-haeufigstes-zeichen-anzahl-ohne-a2-470.png?nocache=1308578366114

Nun wissen Sie, wie man das am häufigsten auftretende Zeichen einer Zelle und seine Anzahl herausbekommen kann. Steht in der Zelle des am häufigsten auftretenden Zeichens nichts, so wundern Sie sich nicht. Bei den Formeln von oben wird auch das Leerzeichen mit einbezogen, was bei ihnen dann wahrscheinlich der Fall wäre. Desweiteren wird auch zwischen Groß- und Kleinschreibung unterschieden. Eine weitere Sache die angemerkt werden muss, ist dass wenn mehrere Zeichen gleich oft  auftreten, das erste von ihnen benutzt wird. Dies ist auch in meinem Beispiel der Fall, so tritt das „s“ und das Leerzeichen gleich oft auf, jedoch wird „s“ als am häufigsten verwendetes Zeichen angesehen, da es zuerst im Text vorkommt („Das “).

Von |2018-07-25T14:23:40+00:00Juni 21st, 2011|Kategorien: Tabellenkalkulation|0 Kommentare

Über den Autor:

Hinterlassen Sie einen Kommentar