Excel Formeln – Satzzeichen entfernen

Haben Sie in Excel einen Satz inklusive Satzzeichen eingetragen und Sie möchten diese nun entfernen, so gibt es nur die Möglichkeit diese manuell zu löschen. Falsch. Mithilfe von ein paar Formeln geht dies auch ganz leicht automatisch.

Wie man einzelne Wörter aus einem String ausgibt, habe ich ihnen hier schon erklärt. Jedoch wurde dabei keine Rücksicht auf Satzzeichen gemacht. In diesem Artikel hingegen werden zuerst aus einem String alle Satzzeichen gefiltert und anschließend werden alle Wörter aufgelistet.

Hilfszelle:

Um die Wörter einzeln zu bekommen, benötigen Sie eine Hilfszelle. Hilfszelle ist in diesem Fall aber gar nicht so ein richtiger Ausdruck. Diese Zelle ist nämlich dazu da, dass in ihr die Satzzeichen entfernt werden. Dies ist ja eigentlich schon das Ziel der Anleitung. Jetzt aber zur Tabelle: In die Zelle A1 schreiben Sie bitte den Text, bei dem die Satzzeichen entfernt werden sollen. Selbstverständlich kann der Text auch in einer anderen Zelle stehen, jedoch müssen dann die Zellbezüge wieder angepasst werden. Nachdem der String eingetragen wurde, kann nun die Formel folgen, die den Text ohne Satzzeichen ausgibt. Gehen Sie dazu in eine noch freie Zelle, am besten wäre die Zelle A2. Hier schreiben Sie die folgende Formel hinein:

=GLÄTTEN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(A$1;",";"");".";"");"!";"");"?";"");";";"");":";"");"""";""))

Da die Formel keine Matrixformel, sondern eine ganz normale ist, reicht es aus, wenn Sie die Formel eingeben und anschließend per Enter Taste bestätigen. Haben Sie das getan, so wird nun in der Zelle der String aus A1 ohne die Satzzeichen angezeigt.

(Zur Darstellung in Originalgröße Abbildungen anklicken)

Erstes Wort:

Da wir ja nun die Hilfszelle haben, kann auch die Anzeige der einzelnen Wörter beginnen. Die beste Wahl hierzu ist die Zelle B1. Gehen Sie also in diese Zelle und geben Sie die folgende Formel ein:

=LINKS(A$2;FINDEN(" ";A$2)-1)

Dies ist eine sehr kurze Formel und sie verfügt auch nur über die Möglichkeit das erste Wort anzuzeigen. Dies wird aber sofort erledigt, nachdem Sie die Formel eingegeben und gegebenenfalls noch mit enter bestätigt haben.

Andere Wörter senkrecht:

Wie schon gesagt, gilt die Formel für oben ja nur für das erste Wort und dementsprechend auch nur für die erste Zelle. Möchten Sie nun, dass auch die anderen Wörter angezeigt werden, so benötigen Sie wieder eine neue Formel. Hier gibt es auch wieder zwei verschiedene Formeln. Zuerst werde ich die Formel behandeln, die die anderen Wörter senkrecht anzeigt, also in der weiteren Zellen der Spalte B. Diese Formel für die Zelle B2 lautet:

=WENN(ZEILE()-1>LÄNGE(A$2)-LÄNGE(WECHSELN(A$2;" ";""));"";WENN(ZEILE()-1=LÄNGE(A$2)-LÄNGE(WECHSELN(A$2;" ";""));TEIL(A$2;FINDEN("##";WECHSELN(A$2;" ";"##";LÄNGE(A$2)-LÄNGE(WECHSELN(A$2;" ";""))))+1;100);TEIL(A$2;FINDEN("#";WECHSELN(A$2;" ";"##";ZEILE()-1))+1;FINDEN("#";WECHSELN(A$2;" ";"##";ZEILE()))-FINDEN("#";WECHSELN(A$2;" ";"##";ZEILE()-1))-1)))

Da diese auch für die anderen Zellen verwendet wird, müssen Sie die Formel noch nach unten kopieren. Klicken Sie dazu die Zelle B2 nochmals an und fahren Sie mit ihrer Maus über die rechte untere Ecke der Zelle. Der Mauszeiger verwandelt sich nun in ein Kreuz. Ist das geschehen, so klicken Sie jetzt mit der linken Maustaste und halten Sie sie gedrückt, während Sie die Maus nach unten ziehen. Die Anzahl an Zellen, die mit der neuen Formel versehen werden, hängt davon ab, wie viele Wörter Sie in die Zelle A1 eingegeben haben.

Haben Sie eine ausreichende Länge erwischt, so wird nun in allen eingeschlossenen Zellen das jeweilige Wort zu sehen sein.

Andere Wörter waagerecht:

Finden Sie es schöner, dass die anderen Wörter waagerecht statt senkrecht angezeigt werden, so geht das selbstverständlich auch. Die Zelle in der das zweite Wort steht (das erste steht in B1) ist somit also C1. Wie schon erwähnt benötigen Sie hierfür wieder eine andere Formel als die für die senkrechten Wörter. Wie auch die anderen beiden Formeln ist die Formel keine Matrixformel. Schreiben Sie deshalb in die Zelle C1 einfach diese Formel:

=WENN(SPALTE()-2>LÄNGE($A2)-LÄNGE(WECHSELN($A2;" ";""));"";WENN(SPALTE()-2=LÄNGE($A2)-LÄNGE(WECHSELN($A2;" ";""));TEIL($A2;FINDEN("##";WECHSELN($A2;" ";"##";LÄNGE($A2)-LÄNGE(WECHSELN($A2;" ";""))))+1;100);TEIL($A2;FINDEN("#";WECHSELN($A2;" ";"##";SPALTE()-2))+1;FINDEN("#";WECHSELN($A2;" ";"##";SPALTE()-1))-FINDEN("#";WECHSELN($A2;" ";"##";SPALTE()-2))-1)))

Nachdem Sie sie eingegeben haben, sollte auch schon das zweite Wort angezeigt werden. Auch eine Bestätigung mit der Enter Taste sollte automatisch erfolgt sein. Diese Formel ist auch für die anderen Zellen der Zeile „1“ gleich, deshalb können Sie die Formel einfach kopieren. Klicken Sie dazu nochmal auf die Zelle C1 und fahren Sie über ihre rechte untere Ecke bis der Mauszeiger in ein Kreuz umgewandelt wird. Nun klicken Sie und halten Sie die Taste wieder, während Sie die Maus einige Zellen nach rechts verschieben (Anzahl ist wieder von der Anzahl Wörter in A1 abhängig).

Wenn Sie eine passende Länge gewählt haben, sind nun alle verwendeten Felder mit einem Wort gefüllt und der Text aus A1 ist aufgeteilt worden.

Nun können Sie auch einen String in seine einzelnen Wörter aufteilen, wenn Satzzeichen vorkommen. Sie haben auch Kontrolle darüber, in welche Richtung die Wörter angezeigt werden sollen.