In diesem Artikel werde ich ihnen zeigen, wie man mit einer Excelformel die Anzahl an unterschiedlichen Zellen in einer Spalte ausgeben kann. Dies funktioniert neben Zahlen auch mit Texten.

Mit der Funktion ANZAHL2 kann man in Excel die Zellen zählen, in denen Inhalt steht. Dabei ist es aber völlig egal, ob der Inhalt doppelt auftritt. Soll aber das auch untersucht werden, so benötigt man dafür eine spezielle Funktion. Wie die aussieht, sehen Sie hier.

Beginn:

In meiner Anleitung stehen in den Zellen A1-A7 die Zahlen, die auf ihr Vorkommen überprüft werden sollen. In der Zelle A9 folgt dann immer jeweils die Formel. Haben Sie mehr als nur sieben Einträge, die überprüft werden sollen, so müssen Sie die Formeln natürlich entsprechend abändern. Um zu demonstrieren wie die Formel später funktionieren wird habe ich in den Zellen auch schon doppelte Zahlen verwendet. So kommen in den Zellen A1-A7 die Zahlen „1“, „3“ und „5“ jeweils einzeln vor, die „2“ und die „4“ hingegen doppelt.

Keine leere Zelle:

Zu Beginn der Anleitung möchte ich ihnen zeigen, wie man es schafft, dass nur die Zellen gezählt werden, in denen kein doppelter Inhalt steht, also der gleiche Inhalt noch nicht vorgekommen ist. Etwas wichtiges, was Sie bei dieser Formel aber beachten müssen ist die Tatsache, dass sie wirklich nur korrekt funktioniert, wenn in dem Datenbereich keine leeren Zellen auftreten. Ist das bei ihnen der Fall, so nehmen Sie nicht diese Formel, sondern lesen Sie einfach den nächsten Schritt der Anleitung. Sind bei ihnen aber alle Zellen ausgefüllt, so schreiben Sie nun in die Zelle A9 die folgende Formel:

=SUMME(1/ZÄHLENWENN(A1:A7;A1:A7))

Diese Formel ist aber eine Matrixformel. Das bedeutet, dass Sie sie nicht einfach ausführen, indem Sie die Formel eingeben und anschließend Enter drücken. Bei einer Matrixformel müssen Sie zunächst die betroffene Zelle nochmals anklicken. In ihrem Fall ist das die Zelle A9. Anschließend klicken Sie oben in die Bearbeitungszeile der Formel. Haben Sie das gemacht, so müssen Sie jetzt nur noch STRG+SHIFT+Enter drücken. Nun werden Sie in der Zelle selbst den richtigen Wert angezeigt bekommen. In meinem Beispiel war es die Zahl „5“. Desweiteren hat sich die oben eingegebene Formel so verändert:

{=SUMME(1/ZÄHLENWENN(A1:A7;A1:A7))}

Haben Sie ihre Zahlen nicht in den Zellen A1-A7 stehen, so ändern Sie die Zellbezüge einfach aus. Diese Formel funktioniert übrigens nicht nur für Zahlen, sondern geht auch mit Text korrekt um.

(Zur Darstellung in Originalgröße Abbildungen anklicken)
01-excel-formeln-anzahl-unterschiedlicher-spalteneintraege-alle-ausgefuellt-470.png?nocache=1308676156821

Mit leeren Zellen (Matrixformel):

Im normalen Gebrauch kommt es aber viel häufiger vor, dass nicht alle Zellen in einem Bereich ausgefüllt sind. Auch für diesen Fall gibt es natürlich wieder eine Formel. Zuerst löschen Sie nun also die aktuelle Formel in der Zelle A9. Haben Sie das gemacht, so geben Sie nun folgendes hier ein:

= SUMME(WENN(A1:A7<>"";1/ZÄHLENWENN(A1:A7;A1:A7)))

Wie Sie an der Überschrift des Kapitels sicherlich schon erahnt haben, ist dies eine Matrixformel. Das heißt also, dass Sie wieder die Zelle und anschließend die Bearbeitungszeile der Formel anklicken müssen. Haben Sie das gemacht, so müssen Sie noch STRG+SHIFT+Enter drücken. Nun wird die Formel korrekt ausgeführt. Angezeigt wird ihnen jetzt, falls Sie alles richtig gemacht haben, die Anzahl an Zellen, die einen noch nicht vorgekommenen Wert besitzen. Natürlich hat sich, wie es für Matrixformeln üblich ist, die Formel wieder verändert. Neu sieht sie so aus:

{=SUMME(WENN(A1:A7<>"";1/ZÄHLENWENN(A1:A7;A1:A7)))}

Haben Sie die Zahlen oder den Text nicht in den Zellen A1-A7 stehen, so müssen Sie die Formeln natürlich entsprechend verändern.

02-excel-formeln-anzahl-unterschiedlicher-spalteneintraege-leer-matrix-470.png?nocache=1308676174349

Mit leeren Zellen (ohne Matrixformel):

Im vorherigen Schritt wurde ihnen gezeigt, wie man auch mit leeren Zellen umgehen kann unter der Verwendung einer Matrixformel. Oftmals kann man die Matrixformeln auch umgehen, so auch in diesem Fall. Haben Sie immer noch das Anliegen leere Zellen mit einzubeziehen, möchten aber keine Matrixformel verwenden, so ist diese Lösung für Sie perfekt. Löschen Sie nun also, was Sie in der Zelle A9 stehen haben, und schreiben Sie die folgende Formel hinein:

=SUMMENPRODUKT((A1:A7<>"")/ZÄHLENWENN(A1:A7;A1:A7&""))

Wie schon gesagt, ist dies keine Matrixformel. Sie sehen das korrekte Ergebnis also sofort, nachdem Sie die Formel in die Zelle und gegebenenfalls noch auf Enter gedrückt haben. Wie bei den anderen Formeln auch, müssen Sie wieder auf den Zellbezug achten. Auch hier macht die Eingabe von Texten anstelle von Zahlen im Bereich A1-A7 keine Probleme.

03-excel-formeln-anzahl-unterschiedlicher-spalteneintraege-leer-normal-470.png?nocache=1308676194781

Mit leeren Zellen (sehr schnell; Matrixformel):

Eigentlich wissen Sie schon über alle Möglichkeiten Bescheid, die Anzahl an Zellen auszulesen, in denen kein doppelter Wert steht. Eine wichtige Sache ist aber noch anzumerken. Haben Sie in der Spalte A eine sehr lange Liste an Daten, so dauert die Berechnung mit den gerade eben aufgeführten Formeln sehr lange. Aber dafür gibt es Abhilfe. Löschen Sie nun wieder den Wert in der Zelle A9 und geben Sie stattdessen die folgende Matrixformel ein:

=SUMME(WENN(A1:A7<>"";VERGLEICH(A1:A7;A1:A7;0)=ZEILE(1:7))*1)

Natürlich müssen Sie auch hier wieder zuerst die Zelle und anschließend die Bearbeitungszeile der Formel anklicken. Danach genügt es, die drei Tasten STRG+SHIFT+Enter gleichzeitig zu drücken. Nun ist in der Zelle der korrekte Wert erschienen und die Formel hat sich wie folgt verwandelt:

{=SUMME(WENN(A1:A7<>"";VERGLEICH(A1:A7;A1:A7;0)=ZEILE(1:7))*1)}

Bei der geringen Anzahl an Daten, die ich in meinem Beispiel habe, werden Sie an der Geschwindigkeit der Formel nichts merken. Je länger der Datenbereich jedoch wird, desto mehr werden Sie merken, wie sehr diese Formel hilft.

04-excel-formeln-anzahl-unterschiedlicher-spalteneintraege-leer-schneller-zahl-470.png?nocache=1308676214341

Nun wissen Sie über die Möglichkeit Bescheid in Excel die Anzahl an Zellen in einem Datenbereich auszugeben, in denen der Wert nicht mehrmals vorkommt. So können Sie beispielsweise eine eigene Mittelwertfunktion neu erstellen