298 Aufrufe
Gefragt in Tabellenkalkulation von
Hallo,

in meinem Excel – Sprachprogramm möchte ich die Wiedergabegeschwindigkeit des Windows Media Player steuern.

Die MP3 Datei rufe ich mit

MediaPlayer = Shell("C:\Programme\Windows Media Player\wmplayer.exe """  & Pfad & Sounddatei & """", vbHide)“ auf.

Ich möchte gerne die Wiedergabegeschwindigkeit des Tones um 50% verringern und auch wieder auf normale Wiedergabe setzen.

Wer kann mit dabei helfen.

Danke

Gerd

2 Antworten

0 Punkte
Beantwortet von beverly_ Experte (3.3k Punkte)

Hi Gerd,

folgenden Code in ein allgemeines Modul:

Option Explicit
Dim objWmp As Object
Dim intEnde As Integer
Public dblRate As Double

' WMP Starten
Sub WMPStart()
  dblRate = 1
  Const sPfad As String = "C:\Musik\" '<== anpassen
  Set objWmp = GetObject("new:{6BF52A52-394A-11d3-B153-00C04F79FAA6}")
    With objWmp
      .Url = sPfad & "Angels Melodie.mp3"
      .settings.volume = 100   ' Lautstärke
      .settings.Rate = dblRate ' Geschwindigkeit
      Do
        DoEvents
        ' Schleife verlassen wenn Makro WMPEnde ausgeführt wurde damit Player geschlossen wird
        If intEnde = 1 Then Exit Do
        .settings.Rate = dblRate
      ' wiederholen bis Lied zuende
      Loop Until .playstate = 1
      .Close
    End With
  Set objWmp = Nothing
  intEnde = 0
End Sub

' WMP bzw. Abspielen beenden
Sub WMPEnde()
    intEnde = 1
End Sub


Erstelle außerdem einen ActiveX-ToogleButton mit folgendem Code:

Private Sub ToggleButton1_Click()
    If ToggleButton1 Then
        dblRate = 0.5
    Else
        dblRate = 1
    End If
End Sub

Bis später, Karin

0 Punkte
Beantwortet von
Hallo Karin,

vielen DANK für deine Hilfe. Jetzt kann ich endlich die einzelne Wörter einer Fremdsprache leichter heraushören.

Gerd
...