Datum berechnen

Question

Guten Morgen an Alle

Ich erstelle gerade eine Exzeltabelle (2003), wo ich eine Formel oder Funktion suche, in der ich wenn ich ein Geburtsdatum eingebe, den letzten Tag vor der Rente als Lösung bekomme.
Meine Datei sieht volgendes vor:
A1 = Geburtsdatum
A2 = 67 (für Jahre)

Die Lösung in A3. Wenn ich Excel sage: Vom Geburtsdatum (21.09.1954) muss ich 67 Jahre arbeiten. Da müsste jetzt das Datum stehen 20.09.2019.

Wenn es dann noch dazu eine Formel gibt, die bis zum Monatsende weiterrechnet, wäre das mein Ergebnis 30.09.2019).


Gruß
inselgerd

Answer 1

Hallo Gerd,

die Formel lautet:

=MONATSENDE(DATUM(JAHR(A1)+A2;MONAT(A1);TAG(A1));0)

Allerdings hast Du Dich um 2 Jahre verrechnet :-)

Gruß
Rainer

Answer 2

in Deinem Beispiel hast Du nur 65 dazu gezählt, was nicht korrekt wäre es wäre was zwischen 67 Jahren und 65 Jahren. 67Jahre arbeiten muss man erst ab einem bestimmten Geburtstag. Was ich zur Zeit aber nicht vorliegen habe.

Gruß Hajo

Answer 3

Hallo Gerd,

es geht auch kürzer

=DATUM(JAHR(A1)+A2;MONAT(A1)+1;0)

Gruß
Rainer

Answer 4

Hallo Hajo und Rainer

Vielen Dank für die schnelle Lösung. Und natürlich habt ihr recht, ich habe nur 65 Jahre duzu gezählt, entschuldigt.

Gruß
Gerd

Answer 5

Hallo Gerd,

beachte die Hinweise auf dieser Seite
Renteneintrittsalter

Gruß Hajo

Answer 6

Hallo Gerd,

das gesetzliche Renteneintrittsdatum erhältst Du mit folgender Formel

=DATUM(JAHR(A1)+65;MONAT(A1)+WENN(JAHR(A1)<1947;0;WAHL(REST(JAHR(A1);18)+1;20;22;24;1;2;3;4;5;6;7;8;9;10;11;12;14;16;18));TAG(A1))

Das Geburtsdatum steht hierbei in A1.

Gruß
Rainer

Answer 7

Hallo ihr Beiden

Vielen Dank für den Hinweis und die richtige Formel.
Das erspart mir eventuelle Rückfragen meiner Kollegen. Danke

Gruß
Gerd

Answer 8

Hallo Rainer

Noch ne kleine Anfrage. Er rechnet jetzt ja bis zum Geburtstagsdatum. Der letzte Arbeitstag ist aber der letzte Tag in dem Monat. Könnte man das noch reinbringen?

Gruß
Gerd

Answer 9

Hallo Gerd,

habe gerade gemerkt, dass die Formel noch einen Fehler hat, sie liefert ab Geburtsjahr 1965 ein falsches Ergebnis.

Habe das, sowie Deinen Zusatzwunsch geändert.

Das ausgiebige Testen überlasse ich Dir, aber von der Logik her, müsste es passen.

=WENN(JAHR(A1)>1964;DATUM(JAHR(A1)+67;MONAT(A1)+1;0);DATUM(JAHR(A1)+65;MONAT(A1)+1+WENN(JAHR(A1)<1947;0;WAHL(REST(JAHR(A1);18)+1;20;22;24;1;2;3;4;5;6;7;8;9;10;11;12;14;16;18));0))

Gruß
Rainer

Answer 10

Hallo Rainer

In der Praxis wird sich zeigen, ob alles stimmt.
Ich danke dir für deine Arbeit.


Gruß
Gerd