Supportnet Computer
Planet of Tech

Supportnet / Forum / Tabellenkalkulation

Kalender auf Zeile





Frage

Hallo zusammen Kann man auf eine Zeile eine Kalender hinzufügen? Danke in voraus /caspi

Antwort 1 von Mike1

Hi caspi,

wie ist das gemeint, was hast Du genau vor ?!? Bescheib doch mal Dein Problem genauer...

Mike

Antwort 2 von Caspi

Hallo Mike,

Wen auf eine Zeile die Jahres Wochen eingegeben sind musste ich auf eine Zeile drunter die Jahres tagen eingeben wenn es möglich ist irgendwie automatisch, und nicht alle Jahres Tagen Manuel eingeben.

Beispiel.

Zeile 1 die Woche 12
Zeile 2 :21, 22, 23, 24, 25,

Zeile eine weitere Spalte Woche 13
Zeile 2 : 28, 29, 30, 31, 1


Das soll aber (beim Zeile 2) irgendwie automatisch für die ganze Jahr automatisch eingegeben werden (nicht Manuel).

1000 Dank in voraus
/Caspi

Antwort 3 von coros

Hi Caspi,

nachfolgende Formel sollte das machen, was Du möchtest.

Als Beispiel:

Eingabe Kalenderwoche = A1
Ausgabe Datum des Montags der Kalenderwoche = A3

=DATUM(JAHR(HEUTE());1;7*A1-3-WOCHENTAG(DATUM(JAHR(HEUTE());;);3)+1)

Den Dienstrag erhälst Du dann mit der Formel

=A3+1

Den Mittwoch mit der Formel

=A3+2

usw. bis Sonntag (+6)

Ich hoffe, das hilft Dir weiter. Bei Fragen melde Dich.

MfG,
coros
Da hier der einzige Lohn für die Helfer eine Rückmeldung ist, wäre es nett, wenn Du ein
Feedback abgeben könntest, ob der Lösungsvorschlag Dein Problem gelöst hat.

Antwort 4 von Arnim

Hallo zusammen,
interessiert hat mich der Titel "Kalender auf Zeile".
So wie coros würde ich die Geschichte auch für vernünftig halten.
In A1 Eingabe der Jahreszahl, also z.B. 2005.
Ab B1, C1 usw. die gewünschten Kalenderwochen, 12, 13 usw.
In B2 die Formel:
=WENN(B$1="";"";WENN(ZÄHLENWENN(B$1:B1;"<>")>5;"";DATUM($A$1;1;7*B$1+ZEILE(A3)-7)))
und runterkopieren und gleichzeitig nach rechts kopieren. (Datums-Format evtl TT)
Es wird also immer nur die 5-Tage-Woche ab Montag ausgewiesen!

Nun schreibt aber Caspi, er will in Zeile 1 die Kalenderwochen und in Zeile2 die die jeweiligen Tage. Hier stellt sich die Frage: WIE?

Vorschlag1:
Jahreszahl wieder in A1, erste ausgewählte Kalenderwoche in B1 z.B. 12.
Formel in C1:
=WENN($B1="";"";WENN(ZÄHLENWENN($B1:B1;B1)<5;B1;B1+1))
und soweit wie gewünscht nach rechts kopieren. (Das ganze Jahr geht natürlich nicht auf das Blatt denn 52*5=260)
Formel in B2:
=WENN(B1="";"";DATUM($A$1;1;7*B$1+WENN(ZÄHLENWENN($B1:B1;B1)>5;1;2+ZÄHLENWENN($B$1:B1;B1))-7))
und nach rechts kopieren.

Vorschlag2:
Jahreszahl in A1, ab B1 die Kalenderwochen 12, 13 usw.
Jetzt werden die Tage in eine Zelle geschrieben! (wie schön!)
Formel in B2:
=WENN(B1="";"";TEXT(DATUM($A1;1;7*B$1+3-7);"TT")&", " &TEXT(DATUM($A1;1;7*B$1+4-7);"TT")&", "&TEXT(DATUM($A1;1;7*B$1+5-7);"TT")&", "&TEXT(DATUM($A1;1;7*B$1+6-7);"TT")&", "&TEXT(DATUM($A1;1;7*B$1+7-7);"TT"))
und nach rechts kopieren.
Der letzte Vorschlag gefällt mir persönlich am allerbesten!!! :-)

Gruß Arnim

Antwort 5 von Caspi

Hallo Armin und Coros

Arnim
Uauuuuuuuuuu mein Gott, fantastisches Ergebnis das ZWEIETE Vorschlag,
du hast noch bessere Lösung gefunden als ich mich gedacht habe.
Millionen Dank.

Coros
Deine Lösung ist auch sehrwahrscheinlich perfekt aber das ist für mich einfach zu hoch gewesen
Jedenfalls ich danke dich viel mal.


Gruss ihr Excel Kings
/Caspi

Ich möchte kostenlos eine Frage an die Mitglieder stellen:


Ähnliche Themen:


Suche in allen vorhandenen Beiträgen: