Supportnet Computer
Planet of Tech

Supportnet / Forum / Tabellenkalkulation

Dropdown in eigener Symbolleiste





Frage

Hallo alle zusammen, mein erste Fragen hier, ich hoffe jemand kann mir helfen!! Ich habe in meine Mappe bereits eine eigene Symbolleite und möchte jetzt noch ein Dropdown in diese Symbolleite einfügen. Das Dropdown soll alle Tabellenblätter beinhalten und diese bei Auswahl dann einblenden. Vielen dank für eure Hilfe im vorhinaus

Antwort 1 von DukeNT

Hallo Bernd,
wie man das über eine eigene Symbolleiste macht kann ich Dir leider nicht sagen aber wenn du in Excel ganz unten links
auf die Pfeile "I< < > >I" gehst und dann die rechte Maustaste drückst werden Dir auch die Tabellen zum auswählen angezeigt.
Gruß Niels

Antwort 2 von coros

Hallo Bernd,

leider nicht ganz verständlich, ob Du händisch eine neue Symbolleiste erstellt hast oder über einen VBA-Code. Nachfolgend ein Script, dass Dir eine Symbolleiste mit einem PopUpMenü erzeugt., dass alle in der Mappe enthaltenen Blattnamen beinhaltet. Wird ein Blatt eingeblendet, wird das ausgewählte Blatt eingeblendet.
Kopiere die Makros in ein StandardModul.

Option Explicit

Dim ComboBox As Object

Sub Eigene_Symbolleiste_erstellen()
Application.ScreenUpdating = False
Dim NeueSymbolleiste As CommandBar, i As Integer

On Error Resume Next
'Symbollieste löschen falls schon vorhanden
Application.CommandBars("Symbolleiste").Delete
  
'Neue Symbolleiste erstellen
Set NeueSymbolleiste = Application.CommandBars.Add( _
     "Symbolleiste", msoBarTop, False, True)

       
Set ComboBox = NeueSymbolleiste.Controls.Add(msoControlComboBox)
    With ComboBox
        .Text = ActiveSheet.Name 'schreibt den Blattnamen des aktiven Blattes in das PopUpMenü
        .Width = 150 'Breite der Schaltfläche
        .TooltipText = "Über das PopUpMenü kann ein Blatt ausgewählt werden. Das Blatt wird dann eingeblendet"
        .OnAction = "ComboBox_Symbolleiste_betätigt" 'Makro, dass bei betätigen des Menüs ausgeführt werden soll
    End With
    
    'PopUpMenü mit Namen aller vorhandenen Tabellenblättern füllen
    For i = 1 To Worksheets.Count
        With ComboBox
        .AddItem Worksheets(i).Name
        End With
    Next

NeueSymbolleiste.Visible = True

End Sub
'########################################################################################################

Sub Symbolleiste_löschen()
Application.ScreenUpdating = False
   On Error Resume Next
   Application.CommandBars("Symbolleiste").Delete
   On Error GoTo 0
End Sub
'########################################################################################################

Sub ComboBox_Symbolleiste_betätigt()
'Hier muss die Zahl am Ende in der Klammer übereinstimmen mit der Position des Menüs in der Symbolleiste
'Im Beispiel ist das PopUpMenü an der Stelle 1
Set ComboBox = CommandBars("Symbolleiste").Controls(1)

'Ausgewältes Blatt einblenden
With Sheets(ComboBox.Text)
.Visible = True
.Activate
End With
End Sub

Ich hoffe, Du kommst klar. Bei Fragen melde Dich.

Solltest Du nicht wissen, wie Du die Makros in Deine Datei bekommst, dann schau mal auf
meiner Homepage in der Rubrik Anleitungen und dort in der Anleitung 2 nach. Dort stelle ich dazu eine bebilderte Anleitung zur Verfügung, die Dir eventuell helfen wird.

MfG,
Oliver

Da hier der einzige Lohn für die Helfer eine Rückmeldung ist, wäre es nett, wenn Du
ein Feedback abgeben könntest, ob der Lösungsvorschlag Dein Problem gelöst hat.

Antwort 3 von Bernd44

Hallo Oliver,

vielen dank
das war genau das was ich brauchte

MfG
Bernd

Ich möchte kostenlos eine Frage an die Mitglieder stellen:


Ähnliche Themen:


Suche in allen vorhandenen Beiträgen: