Supportnet / Forum / Tabellenkalkulation

Ich hab' da ein Problem, ich habe eine ziemlich große Excel-Tabelle, aus der ich aus drei Spalten Werte berechnen möchte. Die erste Spalte enthält verschiedene KFZ-Kennzeichen, die zweite erhält verschiedene Datumsangaben, die dritte enthält die Werte, die ich summieren möchte. Mein Problem ist, dass ich nicht weiss wie ich auf einen Datumsbereich abfragen kann. Ich möchte also in etwas soetwas: Wenn in Spalte A:A das Kennzeichen xyz steht und in Spalte C:C der Datumsbereich vom 01.01.2004 bis 01.01.2004, so soll er mir alle Beträge der Spalten F:F aufsummieren. Hat jemand eine Idee???????

Hi petra,

die "Wenn Funktion" in Excel erreichst Du über Einfügen/Funktion - im dann aufgehenden Fenster die Zeile "Wenn" markieren und mit OK bestätigen.
Nun kannst Du nacheinander Deine Formelbedingungen eingeben: z.B.:"Wenn a2=02.02.2004dannSummec2:c8".
Zur genaueren Eingabe ist entweder der Hilfeassistent oder die F1 Hilfetaste zu gebrauchen.

Hoffe, ich konnte etwas helfen, aber die gesamten komplexen Möglichkeiten des Funktionsfensters hier darzustellen, würde das Forum sprengen.

MfG Systemlord

Hallo Petra,
das ist einfacher als Du denkst!
Schreibe z.B. in I1 das Kfz-Zeichen, in I2 das Anfagsdatum und in I3 das Enddatum.
Formel:
=SUMMENPRODUKT((A2:A100=I1)*(C2:C100>=I2)*(C2:C100<=I3)*F2:F100)
oder aber umständlicher ohne die Hilfszellen in Spalte I:
=SUMMENPRODUKT((A2:A100="N")*(C2:C100>=DATUM(2004;1;1))*(C2:C100<=DATUM(2004;7;20))*F2:F100)
Bezieht sich also auf Juli und das Nürnberger Kennzeichen.
Brauchst Du nur jeweils einen Tag, kannst Du in der Formel einen Datumsbezug weglassen,
also:
=SUMMENPRODUKT((A2:A100=I1)*(C2:C100=I2)*F2:F100)

Gruß Arnim

Hallo Systemlord,
hallo Arnim,

denke das muss ich erst mal "sinken" lassen, kann heute nicht mehr denken!!
Aber ich finde es klasse, so schnell eine fundierte Antwort bekommen zu haben - einfach nur zu empfehlen !!! :-)

Probiere es morgen mal aus - lasse Euch dann 'ne Antwort zukommen.

Herzliche Grüsse
Petra

Hallo Arnim,

auf Deine Art und Weise funktioniert es leider nicht. Die Tabelle sieht wie folgt aus:

Spalte A (Kennzeichen):
xyz
xyz
xyz
xyo
xyo

Spalte B (Datum):
01.01.2004
12.01.2004
13.02.2004
15.01.2004
30.01.2004

Spalte C (Werte):
100
450
200
300
100

Ich möchte also nun, dass alle Werte addiert werden, die das KFZ mit dem Kennzeichen xyz betreffen, und vom Monat 01 sind!!!

Ist das irgendwie möglich ??????

Herzlichen Dank und viele Grüsse
Petra

Hallo Petra,

Arnims Formel funzt schon. Nur wenn du jetzt nicht einen einzigen Tag, sondern die Werte für einen ganzen Monat abfragen willst, dann musst du die Formel entsprechend anpassen udn die Funktion MONAT einbauen.

=SUMMENPRODUKT((A2:A100=I1)*(MONAT(C2:C100)=I2)*(F2:F100))
IN I2 steht dann die Zahl für den jeweiligen Monat als externe Variable.

CU
want2cu

Hallo Petra,
want2cu hat Dir ja dankenswerter Weise schon geantwortet.
Es klappt deshalb nicht auf Anhieb, weil Du Deine Tabelle (zumindest hier im Forum) zuviel veränderst!
Du schriebst:
"Wenn in Spalte A:A das Kennzeichen xyz steht und in Spalte C:C der Datumsbereich vom 01.01.2004 bis 01.01.2004, so soll er mir alle Beträge der Spalten F:F aufsummieren."
Jetzt stehen die Daten auf einmal in Spalte B und die Werte in Spalte C!
Entweder schreibst Du jetzt in I2 1.7.2004 und in I3 den 31.07.2004, dann lautete die Formel:
=SUMMENPRODUKT((A2:A100=I1)*(B2:B100>=I2)*(B2:B100<=I3)*C2:C100)
Oder, wie want2cu schon schrieb:
=SUMMENPRODUKT((A2:A100=I1)*(MONAT(B2:B100)=MONAT(I2))*C2:C100)
oder ausführlich:
=SUMMENPRODUKT((A2:A100="xyz")*(MONAT(B2:B100)=7)*C2:C100)

Gruß Arnim

Jetzt sehe ich gerade, dass ich auch noch einen Fehler gemacht habe: Du wolltest ja die Zahlen vom Januar; also dann in I" 1.1.2004 und in I3 31.1.2004, die Monatszahl in der Formel ist also dann auch 1 - anstatt 7.

Gruß Arnim

Hallo Arnim,

Asche auf mein Haupt - da habe ich aber einen dicken Schreibfehler produziert!!!
Entschuldigung, kommt nie wieder vor.

Übrigens, Deine letzte Formel funktionier einfach genial - super - super!!!!

Ist nun nur noch etwas Arbeit das alles für
130 LKWs einzugeben.

Ich bin echt begeistert. Was bist Du von Beruf???

Vielen, vielen Dank ...

Gruss
Petra

Hallo Petra,
was machst Du denn da??? Du brauchst nicht 132-mal die Formel zu ändern! Ich habe Dir doch das Beispiel mit den Hilfszellen I1 bis I3 gegeben. Die kannst Du natürlich auch wo anders hinsetzen.
Oder schreibe Dir die 132 Nummern irgendwo untereinander hin und nebendran die Spalte mit der Formel. Die kannst Du dann runterkopieren.
Mache es so:
Trage im nächsten Tabellenblatt2 ab A2 untereinander alle 132 Kfz-Nummern ein. In Tabelle2 Zelle B1 schreibe den Monat Januar in der Form: 01.01.2004, in C1 den Monat 01.02.2004 usw. Anschließend formatierst Du diese Datumszellen mit dem "benutzerdefinierten Format" : MMMM
Jetzt steht in den Zellen B1 "Januar", in C1 "Februar" usw.
In Tabelle2 Zelle B2 schreibe diese Formel:
=SUMMENPRODUKT((Tabelle1!$A$2:$A$2000=$A2)*(MONAT(Tabelle1!$B$2:$B$2000)=MONAT(C$1))*Tabelle1!$C$2:$C$2000)
Die Formel kopierst Du nun herunter bis ca. B150 und dann die ganze (noch markerte) Spalte nach rechts bis Dezember.
Jetzt kannst Du in Tabelle1 die Eintragungen bis Zeile 2000 (oder auch bis Zeile 65535) machen und im Tabellenblatt 2 hast Du jeweils die monatliche Auswertung! (die Formel musst du dann zeilenmäßig anpassen, ich habe sie nur bis Zeile 2000 ausgelegt).
Habe ich mich verständlich ausgedrückt???
Na, dann viel Glück!

Gruß Arnim

PS:Beruf???
Ich wollte mal Bundeskanzler werden. Es hat mich aber keiner gewählt. So habe ich jetzt überhaupt keinen Beruf mehr! :-(

• summewenn und
• Summewenn mit Zellverweis in Bedingung
• summewenn über mehrere Spalten
• Summewenn und Summewenn nicht
• 2x summewenn