Frage stellen

Text auseinandernehmen

1.6k Aufrufe
Gefragt in Tabellenkalkulation von ekg Mitglied (303 Punkte)
Hallo,
ich habe eine Tabelle in der in der ersten Spalte folgender Text steht:

Mustermann, Max (xxy) 78876

Ich muß den Text so auseinandernehmen das in der nächsten Spalten
der Nachname Mustermann,
dann der Vorname Max,
dann (XXY)
dann 12345
stehen. Die Namenlänge ist immer unterschiedlich es stehen ca. 200
Daten untereinander.

8 Antworten

0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo,

Formel für B1:

=LINKS(A1;FINDEN(",";A1)-1)

Formel für C1:

=LINKS(WECHSELN(A1;B1&", ";"");FINDEN("(";WECHSELN(A1;B1&", ";""))-1)

Formel für D1:

=LINKS(WECHSELN(A1;B1&", "&C1;"");FINDEN(")";WECHSELN(A1;B1&", "&C1;""))+1)

Formel für E1:

=WECHSELN(A1;B1&", "&C1&D1;"")

Der Ausgangswert steht in A1.

Gruß
Rainer
0 Punkte
Beantwortet von flupo Profi (17.8k Punkte)
Alternativ findest du im Menü "Daten" die Funktion "Text in Spalten".

Gruß Flupo
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo Flupo,

das wollte ich eigentlich auch vorschlagen, aber da damit die Ausgangswerte nicht erhalten bleiben, habe ich mich für Formeln entschieden.

Gruß
Rainer
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo EKG,

meine Formeln funktionieren nicht, wenn im Ausgangswert Leerzeichen fehlen, zuviel sind oder an anderer Stelle stehen.
Die geänderten Formeln berücksichtigen diesen Umstand.

Formel für B1:

=LINKS(WECHSELN(A1;" ";"");FINDEN(",";WECHSELN(A1;" ";""))-1)

Formel für C1:

=LINKS(WECHSELN(WECHSELN(A1;" ";"");B1&",";"");FINDEN("(";WECHSELN(WECHSELN(A1;" ";"");B1&",";""))-1)

Formel für D1:

=LINKS(WECHSELN(WECHSELN(A1;" ";"");B1&","&C1;"");FINDEN(")";WECHSELN(WECHSELN(A1;" ";"");B1&","&C1;"")))

Formel für E1:

=WECHSELN(WECHSELN(A1;" ";"");B1&","&C1&D1;"")


Gruß
Rainer
0 Punkte
Beantwortet von ekg Mitglied (303 Punkte)
Hallo Rainer,

funktioniert perfekt!
Ich habe noch eine Ergänzung. In der Spalte stehen auch manchmal.

Karl, MARTIN 5555

dann funktioniert die Abfrage nicht. Kannst du mir dabei auch helfen?
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo EKG,

ob ich Dir helfen kann, kann ich Dir erst sagen, wenn Du etwas mehr Einblick gewährst.
Zumindest müsstest Du von jedem vorkommenden Textmuster ein Beispiel posten.

Vor- u. Zunamen kann die Formel aber nicht tauschen, das müsstest Du bereits im Vorfeld erledigen.

Gruß
Rainer
0 Punkte
Beantwortet von ekg Mitglied (303 Punkte)
Hallo Rainer,

Mustermann, Max (xxy) 78876

Kunz Martin 5555

hier die beiden Möglichkeiten.
Also manchmal mit Klammer manchmal ohne.

Danke und Gruß

EKG
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo EKG,

wenn Deine Textmuster tatsächlich identisch mit den 2 geposteten Mustern sind, dann....

Formel für B1:

=WENN(ISTZAHL(FINDEN("(";A1));LINKS(A1;FINDEN(",";A1)-1);LINKS(WECHSELN(A1;" ";"#";2);FINDEN(" ";WECHSELN(A1;" ";"#";2))-1))

Formel für C1:

=WENN(ISTZAHL(FINDEN("(";A1));LINKS(WECHSELN(A1;B1&", ";"");FINDEN("(";WECHSELN(A1;B1&", ";""))-2);TEIL(WECHSELN(A1;" ";"#";2);FINDEN(" ";WECHSELN(A1;" ";"#";2))+1;FINDEN("#";WECHSELN(A1;" ";"#";2))-1-FINDEN(" ";WECHSELN(A1;" ";"#";2))))

Formel für D1:

=WENN(ISTZAHL(FINDEN("(";A1));LINKS(WECHSELN(A1;B1&", "&C1&" ";"");FINDEN(")";WECHSELN(A1;B1&", "&C1;""))-1);"")

Formel für E1:

=WENN(ISTZAHL(FINDEN("(";A1));WECHSELN(A1;B1&", "&C1&" "&D1&" ";"");TEIL(WECHSELN(A1;" ";"#";2);FINDEN("#";WECHSELN(A1;" ";"#";2))+1;99))

... wenn nicht, dann musst Du selbst eine Anpassung vornehmen,
oder die Funktion "Text in Spalten" verwenden.

Gruß
Rainer
...