spezielle Summenprodukt-Formel

Question

Hallo zusammen,

mein Problem ist folgendes:
Ich habe eine Spalte A mit fortlaufenden (und mehrfach vorkommenden) Datumswerten. Ich möchte nun alle Werte in Spalte B aufsummieren, wenn das Datum aus Spate A in die gleiche Kalenderwoche fällt.
Das Summenprodukt funktioniert auch soweit ganz gut, allerdings nur mit einer Hilfsspalte, die die Kalenderwoche enthält.



Wahrscheinlich muss ich das ganze mit einer Matrix-Formel darstellen. Leider habe ich damit noch nicht so viel Erfahrung

Answer 1

Die kalenderwoche kann man auch per Formel ermitteln. Ansonsten benutze Summewenns() und gebe denb Montag und Sonntag an.

Gruß Hajo

Answer 2

Hallo HaJo,

Danke für deinen Tipp.
Die Funktion "Kalenderwoche" habe ich für meine Hilfspalte verwendet. Das Problem ist, dass ich die Summewenn/Summenprodukt-Formeln nur mit dieser Hilfspalte verwenden kann. Das liegt daran, dass ich nur jeden Datumswert einzeln mit der Kalenderwochenfunktion berechnen kann.
Gibt es eine Möglichkeit wie etwa
SUMMENPRODUKT((KALENDERWOCHE(A1:A10)>12)*(KALENDERWOCHE(A1:A10)<15)*1) ??
weil soetwas suche ich.

Bin für jeden Tipp dankbar.

Grüße
Paul

Answer 3

Hallo Paul,

was Kürzeres kann ich Dir leider nicht anbieten:

=SUMMENPRODUKT(N(KÜRZEN((A2:A5-DATUM(JAHR(A2:A5+3-REST(A2:A5-2;7));1;REST(A2:A5-2;7)-9))/7)>12)*(N(KÜRZEN((A2:A5-DATUM(JAHR(A2:A5+3-REST(A2:A5-2;7));1;REST(A2:A5-2;7)-9))/7)<15)*(B2:B5)))

Zellbezüge sind eventuell anzupassen

Gruß

Paul1

Answer 4

summewenns() möchtest du also nicht benutzen. Einfach das Datum von Montag und Sonntag /7 für diese Woche.
=SUMMENPRODUKT((E39:E47/7>=5854,28571428571)*(E39:E47/7<=5855,14285714286)*D39:D47)

Gruß Hajo

Answer 5

oder falls es Dir mit Datum besser gefällt.
=SUMMENPRODUKT((E39:E47/7>="12.03.12"/7)*(E39:E47/7<="18.03.12"/7)*D39:D47)

Gruß hajo

Answer 6

Hallo Rudi,

Die von mir gepostete Formel rechnet nicht mit der richtigen Kalenderwoche?

schau mal hier Antwort 1

Gruß

Paul1

Answer 7

Hallo Paul1,

entschuldige, ich hatte mich bei deiner Formel vertan und (voreilig) die Alternative angeboten. 'ist natürlich vollkommen richtig.

Gruß und schönes WE
Rudi

Answer 8

Hallo zusammen,

habe das Problem jetzt gelöst. Habe die Formel aus dem Link von Rudi soweit angepasst, dass ich ein Summenprodukt bilden konnte. Jetzt klappts. Falls es jemanden interessiert, die Formel sieht jetzt so aus:

=SUMMENPRODUKT(((DM(($A$1:$A$23+9)/7;)-DM((6&-1&-JAHR(7*DM(($A$1:$A$23+2)/7;)-2))/7;)>=C6)*((DM(($A$1:$A$23+9)/7;)-DM((6&-1&-JAHR(7*DM(($A$1:$A$23+2)/7;)-2))/7;)<C7)*1)))

Die Datumsreihe steht in der Spalte A. Die Zellen C6 und C7 sind die Unter- bzw. Obergrenzen für die Kalenderwoche. Das Summenprodukt zählt mir jetzt die Anzahl der Datumswerte innerhalb der Grenzen ohne Hilfspalte.

Also, ein dickes Dankeschön an alle, die sich an der Problemlösung beteiligt haben.

Grüße
Paul