ID wiedergeben, wenn 2 Bedingungen erfüllt sind

Question

Hallo,

ich habe ein Problem und hoffe, ihr könnt mir helfen.

Ich habe folgende Tabelle "Report":

g" alt="http://i1085.photobucket.com/albums/j431/bealein/Stuff/table.jp
g" />

Nun möchte ich, dass mir in einer anderen Tabelle in Spalte A all
jene IDs ausgegeben werden, bei denen in "Report" B = GER UND
C = AC oder AM oder AC & AM.

Kann ich das mit Formeln lösen, ohne dass es zwischen den IDs
leere Zeilen gibt?
Ich möchte also, dass durch runterziehen der Formel keine leeren
Zellen existieren, sondern dass die Formel bei Nichtzutreffen der
Bedingungen direkt die nächste ID prüft und so nur wahre
Bedingungen zurückgegeben werden.

Ist das ohne Makro realisierbar? Wenn ja: Wie? ;)

Danke schon mal und viele Grüße :)

Answer 1

Hallo Jelly,

warum sendest Du anstatt eines Bildes keine Excelmappe?

Dort könnte man ohne Nachbau eine funktionierende Formel einbauen.

Gruß
Rainer

Answer 2

Hi Jelly,

folgende Matrixformel sollte helfen, WENN wie in deinem Beispiel die ID's Zahlen sind. Wenn nicht nochmal melden, wird die Formel etwas länger:

ACHTUNG!! MATRIXFORMEL!!

geschweiften Klammern nicht händisch eintragen, sonder mit STRG+SHIFT+ENTER abschliessen.

Die Tabelle mit den Daten ist Tabelle1, dies durch deinen tatsächlichen Namen Tabellennamen ersetzen.
Der Suchbegriff aus Spalte B steht in Tabelle2 B1, der Suchbegriff aus Spalte C in Tabelle2 C1

{=WENN(ISTFEHLER(KKLEINSTE(WENN(Tabelle1!$B$2:$B$200&Tabelle1!$C$2:$C$200=Tabelle2!$B$1&Tabelle2!$C$1;Tabelle1!$A$2:$A$200);ZEILE(A1)));"";KKLEINSTE(WENN(Tabelle1!$B$2:$B$200&Tabelle1!$C$2:$C$200=Tabelle2!$B$1&Tabelle2!$C$1;Tabelle1!$A$2:$A$200);ZEILE(A1)))}

CU Aliba

Answer 3

Danke Aliba, das hilft mir schon mal sehr.
Allerdings macht die Formel momentan noch nicht ganz das, was sie soll. Bisher habe ich als Suchbegriffe "Germany" in B1 stehen und "AC" in C1.
Die Bedingungen sind aber ja eigentlich, dass( B = germany) UND (C = AC oder C = AM oder C = AC & AM).
Die bisherige Formel prüft aber nur, ob B = germany und C = AC. C = AM bzw. C = AC & AM wird aber nicht überprüft.

Kann man das noch in die Formel einbauen?

Answer 4

Achso, ganz vergessen: hier noch die Tabelle, wie es momentan aussieht.
http://www.file-upload.net/download-7705781/test.xlsx.html

Answer 5

Hi Jelly,

{=WENN(ISTFEHLER(KKLEINSTE(WENN(($B$2:$B$200=$E$1)*(ISTZAHL(VERGLEICH($C$2:$C$200;$F$1:$F$10;0)));$A$2:$A$200);ZEILE(A2)));"";KKLEINSTE(WENN(($B$2:$B$200=$E$1)*(ISTZAHL(VERGLEICH($C$2:$C$200;$F$1:$F$10;0)));$A$2:$A$200);ZEILE(A1)))}

Das ist jetzt auf deine Datei angepasst und Du kannst im Bereich F1 bis F10 bis zu 10 verschiedene ODER - Kriterien für Spalte C angeben.

CU Aliba

Answer 6

Perfekt! Vielen Dank, Aliba.
Funktioniert einwandfrei.

Nur eine Frage habe ich noch - das ist aber eher eine Schönheitssache. Wenn das nicht umgesetzt werden kann, dann ist das auch kein Weltuntergang ;)
Die Werte in Spalte C ergeben sich eigentlich aus folgender Formel:
=WENN(ISTZAHL(FINDEN("APPLICATION MODIFICATION";B2));WENN(ISTZAHL(FINDEN("APPLICATION CAPITAL";B2));"AC & AM";"AM");WENN(ISTZAHL(FINDEN("APPLICATION CAPITAL";B2));"AC";))

Ich habe das noch mal in der folgenden Tabelle dargestellt:
http://www.file-upload.net/download-7706286/test.xlsx.html
In Tabelle "Type" steht in C2 die Formel, die die Werte für Spalte C in "Report" liefert.

Ist es möglich, diese Formel zu integrieren, so dass keine Hilfsspalte zur Berechnung nötig ist?

Wie gesagt, wenn das nicht geht, dann ist es auch nicht schlimm ;)

Vielen Danken auf jeden Fall schon mal für deine bisherige Hilfe :)

Answer 7

Hallo Jelly,

da Du eine Excelversion >2003 verwendest, lässt sich die Formel von Aliba wie folgt optimieren.

=WENNFEHLER(KKLEINSTE(WENN(($B$2:$B$200=$E$1)*(ISTZAHL(VERGLEICH($C$2:$C$200;$F$1:$F$10;0)));$A$2:$A$200);ZEILE(A1));"")

Das nur als Hinweis.

Gruß
Rainer

Answer 8

Hi Jelly,

so ganz verstehe ich nicht. Du hast hier das Tabellenblatt "Report", sowie das Tabellenblatt "Type". In beiden gibt es eine Spalte C.
In Type werden die Kürzel mit Deiner obigen Formel erzeugt.
Welche Spalte C willst Du dir den sparen, die in Type oder die in Report??

CU Aliba


@Rainer: Wird wohl langsam Zeit sich mal mit den "neuen" Funktionen auseinanderzusetzen.
Bei ISTFEHLER muss man ja sagen, wenn dies einen Fehler erzeugt dann mache jenes, ansonsten mache dieses.
Bei WENNFEHLER scheint es ja so zu sein, daß man sagt :
Mach dies,ausser es gibt einen Fehler , dann mach jenes. Man muss quasi die Ursprungsanweisung nicht mehr zu wiederholen.
Muss ich mir unbedingt merken, spart viel Tipperei.

CU Aliba

Answer 9

@ Aliba

...genau so ist es.

WENNFEHLER() ist schon ein guter Ersatz für ISTFEHLER(), ISTNV() etc., der Zeit spart und komplexe Formeln freundlicher aussehen lässt.

Gruß
Rainer

Answer 10

Ich möchte mir gerne die Spalte C in "Type" sparen.
Deshalb meine Frage, ob es möglich ist, die Generierung der Kürzel durch die oben genannte Formel (aus Spalte C in "Type"), in die von dir generierte Formel zu integrieren?