Frage stellen

Wie berechne ich den Neukundenanteil zu den Vorjahren?

2.7k Aufrufe
Gefragt in Tabellenkalkulation von
Hallo ihr Excel-Wissende

Ich habe eine 1345 Zeilen lange Liste mit Kundenumsätzen pro ausgestellter Rechnung über 6 Jahre (2008 - 2013). Nun möchte ich gerne den Neukundenanteil in Anzahl Kunden und Umsatz ermitteln. Also, wie viele Kunden sind im 2013 im Vergleich zu den Vorjahren hinzugekommen und wie viel macht deren Umsatz im 2013 aus.

Spalte A: Rechnungsdatum
Spalte B: Kundennamen
Spalte C: Rechnungsbetrag

Weiss jemand wie das geht?

Schon mal Danke im Vorraus!!

LG, Ela71

8 Antworten

0 Punkte
Beantwortet von paul1 Experte (4.9k Punkte)
Hallo Ela,

Ein Konzept, welches das gewünschte Ergebnis bringt, schau Dir den grün eingefärbten Bereich an.

Die Zellbezüge in den Formeln sind natürlich logisch an die Gegebenheiten anzupassen.

Gruß

Paul1

http://www.file-upload.net/download-8447284/Neukunden.xls.html
0 Punkte
Beantwortet von
Hallo Paul1

Kann dein File nicht downloaden, da ich keinen Account besitze resp. keine Kreditkarte, die man benötigt, um den Account zu eröffnen.

Kann man das irgendwie anders lösen?

Grüsse

Ela71
0 Punkte
Beantwortet von paul1 Experte (4.9k Punkte)
Hallo Ela71,

Es ist im Forum üblich, Beispiele hochzuladen um sich eine Menge Schreibarbeit zu ersparen, Deine Antwort2 kann ich nicht verstehen (Kreditkarte, Account wozu?)

A1:C10:

RechnungsdatumKundennameRechnungsbetrag
31.12.2008 Berger 100
01.09.2009 Müller 50
02.10.2010 Meier 200
03.08.2011 Brunner 300
06.03.2012 Kramer 400
05.01.2013 Krames 200
08.02.2013 Bauer 250
09.03.2013 Berger 400
18.05.2013 Brunner 1000

Folgende Formeln:

H2:

=WENN(ISTNV(INDEX($C$7:$C$10;VERGLEICH($B$2:$B$6;$B$7:$B$10;0)));"x";INDEX($C$7:$C$10;VERGLEICH($B$2:$B$6;$B$7:$B$10;0)))

und runterkopieren

für Summe Neukunden I2:

=SUMME(C7:C10)-SUMME(H2:H6)
Ergebnis: 450,--

für Anzahl Neukunden J2:

=ANZAHL(C7:C10)-ANZAHL(H2:H6)
Ergebnis: 2

Die Zellbezüge sind anzupassen

Gruß

Paul1
0 Punkte
Beantwortet von
Lösung mit Hilfsspalte:

Formel in D2 und bis D1500 nach unten kopiert:

=(SUMMENPRODUKT(($B$2:$B$1500=B2)*1)=SUMMENPRODUKT(($B$2:$B$1500=B2)*(JAHR($A$2:$A$1500)=2013)))*1

Formel für die Anzahl Neukunden: =SUMME(D2:D1500)
Formel für den Umsatz Neukunden: =SUMMENPRODUKT(C2:C1500;D2:D1500)
0 Punkte
Beantwortet von
Hi, nochmal ich.

Die Anzahl Kunden passt nicht, Summe schon.

Muss nochmal schauen. melde mich noch einmal.
0 Punkte
Beantwortet von
So, da bin ich dann noch einmal.
Auf die Schnelle ist mir dann nur eine Lösung mit einer 2. Hilfsspalte eingefallen:

Formel in D2 und nach unten kopiert:

=(ZÄHLENWENN($B$2:B2;B2)=1)*(SUMMENPRODUKT(($B$2:$B$1500=B2)*1)=SUMMENPRODUKT(($B$2:$B$1500=B2)*(JAHR($A$2:$A$1500)=2013)))*1

Formel in E2 und nach unten kopiert:

=(SUMMENPRODUKT(($B$2:$B$1500=B2)*1)=SUMMENPRODUKT(($B$2:$B$1500=B2)*(JAHR($A$2:$A$1500)=2013)))*C2

Anzahl: =SUMME(D2:D1500)
Summe Umsatz: =SUMME(E2:E1500)

Gibt sicherlich eine elegantere Lösung, aber da fehlt mir momentan die Zeit.

Zu solchen Auswertungen solltest du dir auch mal die Pivot-Tabellenauswertung anschauen und ein wenig probieren.
0 Punkte
Beantwortet von paul1 Experte (4.9k Punkte)
Hallo Ela71,

Mein Lösungsvorschlag aus AW3 funktioniert nur solange, als es im laufenden Jahr keine doppelten gibt.

Das kommt davon, wenn man nicht ausgiebig testet, bevor man eine Antwort absendet.

Gruß

Paul1
0 Punkte
Beantwortet von
Super! Vielen, vielen Dank Aliba. Die Formel funktioniert 1A!

LG,

Ela71
...