Zahlenreihe trennen

Question

Hallo! Ich bitte um Hilfe bei folgendem Problem in Excel 2003.
In A1 steht
02.11.67-23456
Es handelt sich um ein Geburtsdatum und eine Kennummer, getrennt duch Bindestrich.
Ich bitte um eine Formel, die in A2 nur das Geburtsdatum ausweist, also 02.11.67 .

Zusatzfragen 1:
Wie muss die Formel lauten, wenn das Datum in A1 ohne Punkt gesetzt ist, also 021167-23456 und ich 021167 in A2 ausweisen möchte?

Zusatzfragen 2:
Wie muss die Formel lauten, wenn das Datum in A1 mit Punkt und vierstelliger Jahreszahl gesetzt ist, also 02.11.1967-23456 und ich 02.11.1967 in A2 ausweisen möchte?

Zusatzfragen 3:
Wie muss die Formel lauten, wenn das Datum in A1 ohne Punkt und mit vierstelliger Jahreszahl gesetzt ist, also 02111967-23456 und ich in A2 02111967 stehn haben möchte?

Recht vielen Dank für eure Hilfen!

Gruss
Uwe

Answer 1

Hi,


=TEIL(A1;1;FINDEN("-";A1;1)-1) sollte Deinen Wünschen entsprechen.


Bye
malSchauen

Answer 2

Vielen Dank für die rasche Antwort. Es funktionert. Allerdings habe ich noch eine Zusatzfrage, die sich erst jetzt ergeben hat.
Es gelingt mir nicht, Geburtsdaten, die in A2 ohne Punkt ausgwiesen werden, ins Datum-format umzuwandeln. Dies ist aber notwendig, da ich mithilfe einer DATEDIF - Formel in A3 das aktuelle Alter ausweisen möchte.

Wie löse ich das Problem?

Danke für Eure Hilfen!

Uwe

Answer 3

Hallo Uwe,

Zusatzfrage1

=--(LINKS(LINKS(A1;FINDEN("-";A1)-
1);2)&"."&TEIL(A1;3;2)&"."&TEIL(A1;5;2))

Zusatsfrage 2

=--LINKS(A1;FINDEN("-";A1)-1)

Zusatzfrage 3

=--(LINKS(LINKS(A1;FINDEN("-";A1)-
1);2)&"."&TEIL(A1;3;2)&"."&TEIL(A1;5;4))

Mit diesen Formeln erhältst Du das Daten im richtigen
Datumsformat.

Gruß
Rainer

Answer 4

Prima! Recht vielen Dank an malSchauen und Rainer. Es funktioniert.
Gruss
Uwe

Answer 5

Hi,

Eine Version alle 4 Eingabe-Möglichkeiten mit einer Formel abzudecken:

- Zelle mit der folgenden Formel als "Datum" formatieren
- folgende Formel einfügen:

=WENN(A1<>0;WENN(ISTFEHLER(FINDEN(".";A1));DATWERT(LINKS(TEIL(A1;1;FINDEN("-";A1;1)-1);2)&"."&TEIL(A1;3;2)&"."&TEIL(A1;5;FINDEN("-";A1;1)-5));DATWERT(TEIL(A1;1;FINDEN("-";A1;1)-1)));"")

bye
malSchauen

Answer 6

Hi,

@Rainer (rainberg)
Da ich auf die Schnelle nicht fündig werde: Was bedeuten die beiden Minuszeichen am Beginn der Formeln aus #3? Ich sehe zwar die Auswirkungen wenn ich sie weglasse, kann mir aber aus dem Stand keinen wirklichen Reim darauf machen.

Bye
malSchauen

Answer 7

Hi,

@Rainer
Ziehe meine Frage zurück. ;-)
Sehr geschickte "Typumwandlung". Hat zwar gedauert, aber ich glaube das ist es. Muss ich mir unbedingt merken.

Bye
malSchauen

Answer 8

Hallo,

@malSchauen

hast Du richtig erkannt, anstatt von -- könnte man den entsprechenden
Formelteil auch mit 1 multiplizieren.
Bei Deiner Formel könntest Du auf die Funktion DATWERT() verzichten indem
Du das Gesagte anwendest.

=WENN(A1<>0;WENN(ISTFEHLER(FINDEN(".";A1));--
(LINKS(TEIL(A1;1;FINDEN("-";A1;1)-
1);2)&"."&TEIL(A1;3;2)&"."&TEIL(A1;5;FINDEN("-";A1;1)-5));--TEIL(A1;1;FINDEN("-
";A1;1)-1));"")

oder

=WENN(A1<>0;WENN(ISTFEHLER(FINDEN(".";A1));(LINKS(TEIL(A1;1;FINDEN
("-";A1;1)-1);2)&"."&TEIL(A1;3;2)&"."&TEIL(A1;5;FINDEN("-";A1;1)-
5))*1;TEIL(A1;1;FINDEN("-";A1;1)-1))*1;"")

Gruß
Rainer