Frage stellen

werte aus Zeichenfolge

2.6k Aufrufe
Gefragt in Tabellenkalkulation von
Hallo Spezies!
Ich habe eine Spalte mit folgenden Angaben:

EM-I-08-17
EM-I-08-18
EM-I-08-18-0
EM-I-08-18-1

In eine weitere Spalte benötigen ich daraus folgende Werte:

17
18
18
18

Ich habe es schon mit "Suchen" und "Finden" und so versucht, aber nicht wirklich erfolgreich.

Für rasche Hilfe wäre ich sehr dankbar!

Gruss

Platin7

10 Antworten

0 Punkte
Beantwortet von marie Experte (2k Punkte)
Wenn das immer eine zweistellige Zahl an derselben Stelle ist, dann mit
=TEIL(A1;9;2)

wenn zum Beispiel in A1,

wenn nicht musst Du bitte dazusagen was änderbar ist? Also die Anzahl der Zeichen davor oder die Anzahl der zeichen innerhalb der Bindestriche, ist die gleichbleibend?

Gruß Marie
0 Punkte
Beantwortet von
Hallo Marie!

Leider kann die Anzahl der Zeichen zwischen den Bindestrichen variabel sein!
Der Inhalt kann somit auch so aussehen: EM-I-08-188-0
Die ersten Acht Zeichen bleiben jedoch konstant!

Gruss

Ines
0 Punkte
Beantwortet von marie Experte (2k Punkte)
bevor ich jetzt wieder was falsches zusammenbossele sage bitte genau was alles geändert sein kann:

Also ab Zeichen 9 bleibt konstant?? sind das immer nur Ziffern oder nicht?
0 Punkte
Beantwortet von
Also:

Die ersten Acht Zeichen von links bleiben konstant, die nachfolgenden sind variabel!

Der auszugebene Wert ist immer eine Zahl!
0 Punkte
Beantwortet von marie Experte (2k Punkte)
=WERT(TEIL(A1;9;FINDEN("-";A1)))
0 Punkte
Beantwortet von
Hallo Ines,

versuchs mal hiermit:

=WENN(ISTFEHLER(LINKS(TEIL(A1;9;100);FINDEN("-";TEIL(A1;9;100))-1)*1);TEIL(A1;9;100)*1;LINKS(TEIL(A1;9;100);FINDEN("-";TEIL(A1;9;100))-1)*1)

Die Fomel liefert , wenn nach dem 8. Zeichen kein "-" mehr kommt,
die letzten Ziffern als Zahl. Sollte noch einmal ein "-" vorkommen, dann liefert die Formel die Ziffern nach dem 8. Zeichen und vor dem nächsten "-".

CU Aliba
0 Punkte
Beantwortet von marie Experte (2k Punkte)
hi Aliba, bin gerade bissel verwirrt von meinem komischen Ergebnis, sag mir bitte mal was das soll:

EM-I-08-17
EM-I-08-18
EM-I-08-18-0
EM-I-08-18-1
EM-I-08-173
EM-I-08-180
EM-I-08-185-0
EM-I-08-1008-1


hatte diese Zeilen zum Testen,
=TEIL(A1;9;FINDEN("-";RECHTS(A1;9)))

bringt mir dann die ersten vier Zeilen korrekt, in Zeile 5-7 eine 1 und in der letzten eine 100???

=WERT(TEIL(A1;9;FINDEN("-";A1)))
dagegen brachte mir die Ergebnisse:
17
18
#WERT!
#WERT!
173
180
185
100


Um herauszufinden wie das kommt probierte ich
=TEIL(A1;9;FINDEN("-";A1))


und bekam folgendes Ergebnis:
17
18
18-
18-
173
180
185
100


kannst Du mir das mal erklären?? Eigentlich arbeite ich ja nichts mit Excel, aber ich dachte das müsste doch genauso gehen wie in VB: der mitllere String ab Zeichen 9 bis ein Zeichen vor dem nächsten Vorkommen des zeichens "-". Dass es erstmal fehlerhaft war ist mir klar, nur das Ergebnis ist mir schleierhaft in allen Fällen. Kannste mir das mal erklären??

Gruß marie
0 Punkte
Beantwortet von
Hallo Ihr beiden!

Danke für Eure Hilfe!

Aliba`s Lösung hat mir weitergeholfen!
Danke dafür!

Gruss
Ines
0 Punkte
Beantwortet von
Hallo Marie,

dann will ich das mal versuchen:

1. Formel:

=TEIL(A1;9;FINDEN("-";RECHTS(A1;9)))

Die Formel erwartet folgende Anweisungen nach der Klammer:

den text aus dem ein Teil geliefert wird (bei uns Inhalt von A1)
dann die 1. Stelle innerhalb des Strings von A1
und anschliessend noch die Anzahl der zu liefernden Stellen.

Der Knackpunkt ist die letzte Anweisung in Deiner Formel.
Die nehmen wir mal auseinander:
RECHTS(A1;9) ergibt für den Eintrag EM-I-08-185-0 das Ergebnis:

-08-185-0 und in diesem Ergebnis suchst Du nun nach "-". Hier wird nun natürlich von links gesucht, das Ergebnis ist: 1
Also ergibt sich folgende Formel:

TEIL(A1;9;1) also 1 Stelle aus A1 beginnen an Stelle 9, somit eben die Stelle 9, das ist halt eine 1


2. Formel:

=WERT(TEIL(A1;9;FINDEN("-";A1)))

Wieder ist der 3. Teil das Problem:

Ergebnis von
FINDEN("-";A1) ist immer 3, weil die ersten 8 Zeichen immer konstant sind, und somit das erste "-" immer an der dritten stelle steht.

Somit bekommst Du immer die Stellen 9,10 und 11 geliefert.
Das bedeutet bei den Einträgen
EM-I-08-18-0
EM-I-08-18-1

die Ergebnisse 18-
Von diesen Ergebnissen willst Du nun jedoch noch den WERT
haben . 18- ist eben kein Wert und führt somit zur Fehlermeldung

3.Formel :

siehe 2. Formel

Hoffentlich habe ich mich verständlich ausgedrückt

CU Aliba
0 Punkte
Beantwortet von marie Experte (2k Punkte)
Jo, danke, hat nicht wirklich was mit excel zu tun, hatte Mattscheibe. Is halt schwierig das mit links und rechts :-))

Ich wollte eigentlich die ersten 8 Stellen ignoriert wissen, zählen ab Stelle 9 nach rechts, also irgendwie ging ich von der Voraussetzung aus:
TEIL(A1;9;FINDEN("-";A1))
würde heissen: der teil von A1 ab Stelle 9 bis Stelle ..... finde das nächste "-" danach.

Irgendwie bin ich immer noch überzeugt das müsste irgendwie gehen, wenn auch verwurschtelt??

=TEIL(A1;9;LÄNGE(A1)-8)
sind die Stellen ohne die ersten 8

=FINDEN("-";TEIL(A1;9;LÄNGE(A1)-8))-1
ergibt die Anzahl der gesuchen Zeichen

ergibt aber Fehlermeldung, wenn kein "-" Zeichen mehr kommt nach Stelle 8

upps, jetzt kapier ich,
= WENN(FINDEN("-";TEIL(A1;9;LÄNGE(A1)-8))> 0;"gefunden";"nix")

bringt mir auch Fehler, wenn das Zeichen nicht vorhanden, deshalb hast Du geschrieben
WENN(ISTFEHLER................

also muss ich schreiben

= WENN(ISTFEHLER(FINDEN("-";TEIL(A1;9;LÄNGE(A1)-8)));"alle Stellen ohne die ersten 8";"Zeichen von 9 bis gefundenem - ")


jo funzt, supi, dankääääääääääääääääääää, hat mir doch keine Ruhe gelassen, dass ich so eine mattscheibe hatte.

=TEIL(A1;9;WENN(ISTFEHLER(FINDEN("-";TEIL(A1;9;LÄNGE(A1)-8)));LÄNGE(A1)-8;FINDEN("-";TEIL(A1;9;LÄNGE(A1)-8))-1))


Gruß marie
...