Apostroph in den Zellen nach Übernahme aus dem CRM

Question

Hallo an die Profis,

ich hole ja meine Daten aus dem CRM und hatte bisher keine Probleme damit. Wir haben zusätzlich eine Spalte erledigt eingefügt, wenn die Aufträge erledigt sind.

Mit dieser Formel habe ich mir Informationen aus allen Aufträgen, die noch nicht abgearbeitet sind (nicht mit x gekennzeichnet), in diverse Tabellen gespeichert.

=INDEX(Uebernahme!A:A;KKLEINSTE(WENN(Uebernahme!C$3:C$2010<>"x";ZEILE($3:$2010));1))

dies wollte ich nun weiterführen mit folgender Formel

=INDEX(Uebernahme!A:A;KKLEINSTE(WENN(Uebernahme!D$3:D$2010="44";ZEILE($3:$2010));1))

nämlich Informationen aus allen Aufträgen, die in KW44 fertiggestellt werden müssen.

Die Information "44" stammt aber aus dem CRM und ich erhalte ständig Zahlenfehler, dem Wert 44 ist aus dem CRM raus ein Apostroph vorgestellt.

Bisher ist es mir nur gelungen, den Wert einer einzelnen Zelle über die Fehlerkorrektur zurückzuverwandeln, aber nicht über die ganze Tabelle.

Welche Möglichkeiten gibt es? Oder kann ich meine Formel ändern (was mir am liebsten wäre!)

Vielen Dank im voraus für eure Mühe!

Irene

Answer 1

Hallo Irene,

Habe herumexperimentiert mit der Formel allerdings nur im gleichen Tabellenblatt

{=INDEX(A:A;KKLEINSTE(WENN(WECHSELN($D$3:$D$2010;"'";"")="40";ZEILE($3:$2010));ZEILE(A1)))}

Wenn die Zellen der Spalte (Quelldatei) in der 40 drinnen stehen als Text formatiert sind, läuft es wie geschmiert.

Vielleicht liegt es daran.

Mehr konnte ich bis jetzt nicht feststellen, aber ich bleibe am Ball, da es auch mich interessiert.


Schöne Grüße

Paul1

Answer 2

Hallo Irene,

habe Dir mal in allen 3 Mappen die Formeln nach meinem Verständnis angepasst.
In den gelben Bereichen sind die Formeln geändert.
Beachte auch die Zelle A1 in den KW-Bättern, hier wird die KW aus den Blattnamen ausgelesen und in den Formeln verwendet.
Habe auch den Namen "Kalenderwoche" definiert um die Formeln in den KW-Blättern zu vereinfachen.
Wie die Semikola vor der Zahl am einfachsten entfernt werden können, ist in der Auftragsliste beschrieben.

Im Moment habe ich keine Zeit für weitere Erklärungen, kannst aber ruhig fragen, ich antworte spater.

www.file-upload.net/download-2965648/Auftraege-Tabelle-Irene-2-.xlsx.html
www.file-upload.net/download-2965657/Auftraege-offen-2-.xlsx.html
www.file-upload.net/download-2965661/Auftragsliste-2-.xlsx.html

Gruss
Rainer

Answer 3

Vielen Dank für eure Antworten, das sieht alles sehr sehr gut aus ...

vielleicht komm ich noch am WE dazu, das in der großen Tabelle umzusetzen, aber spätestens am Montag!

Ein schönes WE wünscht euch die Irene

Answer 4

Hallo, Rainer,

vielen Dank für deine Hilfe, vielen Dank auch dir, Kalle, wobei die Formel von Rainer schon sehr viel weiter geht und ich mich deshalb mit dieser beschäftigt habe.

Bisher habe ich die "Auftragsliste" bearbeitet, deine Variante das Apostroph weg zu bekommen, ist absolut cool. Es ging um den Apostroph, der vom CRM System im Bereich Kalenderwoche eingetragen war und der zur Fehlermeldung geführt hatte.

3. Das Semikolon in Spalte E wird entfernt, indem man
a) die gesamte Spalte markiert, dann
b) Daten
c) Text in Spalten
d) Weiter
e) Haken bei Tabstopp entfernen
f) Fertigstellen


Die Tabelle mit den offenen Aufträgen läuft wie geschmiert, ich hab es geändert und das passt hervorragend in meiner großen Tabelle:

{=WENN(ZÄHLENWENN(Uebernahme!$C$3:$C$2010;"<>x")>=ZEILE(A1);INDEX(Uebernahme!B:B;KKLEINSTE(WENN(Uebernahme!$C$3:$C$2010<>"x";ZEILE($3:$2010));ZEILE(A1)));"")}

Wo ich jetzt noch zu knabbern habe, ist die Namensdefinition:

=--TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+3;31)

es erscheint z.B. 45 und das Tabellenblatt heißt KW45

und die Verwendung hierbei:

=WENN(ZÄHLENWENN(Kalenderwoche;$A$1)>=ZEILE(A1);INDEX(offen!A:A;KKLEINSTE(WENN(Kalenderwoche=45;ZEILE(INDIREKT("3:"&VERGLEICH(0;Kalenderwoche;-1)+2)));ZEILE(A1)));"")

Kannst du mir bitte in einem oder auch mehreren Sätzen erklären, was hier passiert? Vielen Dank

Irene

Answer 5

Hallo Irene,

das hast Du schon richtig erkannt, die Formel

=--TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+3;31)

generiert aus dem jeweiligen Blattnamen die Zahl, die für die Kalenderwoche steht, vorausgesetzt die Blattnamen lauten, wie in Deiner Datei, KW01,KW02.....KW10, KW45 usw.
Dieser Wert, steht dann in jedem Blatt in A1 oder auch in einer Zelle Deiner Wahl
Das hat den Vorteil, dass Du in jedem Blatt die gleiche Formel verwenden kannst indem Du darin den Bezug auf A1 verwendest.

Der definierte Name "Kalenderwoche" repräsentiert den Bereich der Spalte D im Blatt "offen" der Mappe "Aufträge offen" in dem wirklich Werte stehen, durch folgende Formel in der Namensdefinition wird dieser Bereich dynamisch gehalten, egal wieviel Werte sich darin befinden.

=BEREICH.VERSCHIEBEN(offen!$D$3;;;VERGLEICH(0;offen!$D:$D;-1)-2;)

Ich gehe mal davon aus, dass Du weißt, wie und wo man Namen definiert, denn in Deiner Beispieldatei sind ja schon jede Menge Definitionen vorhanden.

Gruss
Rainer

Answer 6

Hallo, Rainer,

merkwürdigerweise ist in deiner Tabelle alles in Ordnung, sobald ich aber die Formel

=--TEIL(ZELLE("Dateiname";$A$1);FINDEN("]";ZELLE("Dateiname";$A$1))+3;31)

in meine Tabelle kopiere, dann bleibt sie als Formel stehen und es passiert überhaupt nix. Könnte es sein, dass es was mit der Officeversion zu tun hat?

Schönen Gruß

Irene

Answer 7

Hallo Irene,

ich vermute Deine Zelle ist als Text formatiert!?

Formatiere sie als Standard, setze den Cursor in die Eingabezeile und drücke Enter.
Nach dem Abspeichern der Mappe sollte das richtige Ergebnis erscheinen.

Gruss
Rainer

Answer 8

Hallo, es hat alles super super genial geklappt, ich bin total begeistert!

Vielen Dank, das sieht richtig gut aus!

Schönen Abend und nochmals vielen Dank

Irene

Answer 9

Hallo, ich brauch mal wieder eure Hilfe!

Und immer mit einem ganz ähnlichen Problem:

Mit dieser Formel

=WENN(ZÄHLENWENN(Uebernahme!$V$3:$V$2000;"<>")>=ZEILE(A1);INDEX(Uebernahme!B:B;KKLEINSTE(WENN(Uebernahme!$V$3:$V$2000<>"";ZEILE($3:$2000));ZEILE(A1)));"")

möchte ich, sobald in einer bestimmten Spalte irgendein Wert steht, die Inhalte einiger Zellen dieser Zeile in eine andere Tabelle kopiert haben.

Dies funktioniert sehr gut, aber wenn keine Einträge mehr da sind, bekomme ich wieder für jedes Feld den #Zahl - Fehler

Wenn ich in der Abfrage drinstehen habe, immer wenn ungleich x, dann funktioniert es wieder einwand frei.

=WENN(ZÄHLENWENN(Uebernahme!$V$3:$V$2000;"<>x")>=ZEILE(A1);INDEX(Uebernahme!B:B;KKLEINSTE(WENN(Uebernahme!$V$3:$V$2000<>"x";ZEILE($3:$2000));ZEILE(A1)));"")

Gibt es eine andere Möglichkeit, abzufragen, ob ein Wert drin steht? Da es relativ viele verschiedene Werte sind, kann ich nicht jeden einzelnen Wert abfragen!

Vielen Dank schonmal!

Answer 10

Hallo Irene,

neue Fragen gehören in einen neuen Thread, zumal dieser Thread von Dir bereits als gelöst gekennzeichnet war.
Ausserdem macht es keinen Spass einen Zusammenhang zwischen Deiner erneuten Frage und den bereits gegebenen Antworten zu suchen.

Eine erneute Beispieldatei wäre dabei auch nicht schlecht.


Feedback wäre nett
Gruss Rainer
_____________________
Windows 7 Ultimate (x64)
Office 2007 Ultimate
Office 2003 Professional