Wenn-Abfrage mit Vergleich

Question

Hallo liebe Wissenden,

kurzer Umriss der Problemstellung:

Ich habe zwei Tabellen in unterschiedlichen Ordnern.
In der ersten Tabelle sind meine Suchwerte nach denen in der zweiten Tabelle gesucht werden soll.
Existieren die gesuchten Kriterien (gleiche Zeile) in der in der zweiten Tabelle dann soll in die erste Tabelle hinter dem zu suchenden Kriterium ein "übergeben" erscheinen.
Existieren die gesuchten Kriterien nicht in der gleichen Zeile, also ein Kriterium nicht erfüllt dann soll "in Bearbeitung" erscheinen.

Diese Abfrage habe ich versucht mit folgender Formel zu realisieren:

=WENN(UND(VERGLEICH($B$1;[_Projektliste.xlsm]Tabelle1!$A:$A;0);VERGLEICH($C18;[_Projektliste.xlsm]Tabelle1!$M:$M;0));"übergeben";"in Bearbeitung")

-> Scheint auf den ersten Blöick auch gut zu funktionieren.

Hinter dem gesuchten Kriterium erscheint auch der Text "übergeben".
Lösche ich jedoch diesen Wert aus der Tabelle2 dann erscheint das #NV und nicht der Text "in Barbeitung".

Woran kann das liegen?
Oder ist die Formel für diese Abfrage etwa ungeeignet?

Vielen Dank und beste Grüße,

Kapa

Answer 1

Hallo,

es liegt daran, dass eie Vergleichsbedingung nicht erfüllt ist.

Versuch es mal so

=WENN(UND(VERGLEICH($B$1;[_Projektliste.xlsm]Tabelle1!$A:$A;0);VERGLEICH($C18;[_Projektliste.xlsm]Tabelle1!$M:$M;0));=WENN(UND(VERGLEICH($B$1;[_Projektliste.xlsm]Tabelle1!$A:$A;0);VERGLEICH($C18;[_Projektliste.xlsm]Tabelle1!$M:$M;0));"übergeben";"in Bearbeitung");"")

Gruß

Helmut

Answer 2

Hallo,

mein Vorschlag geht nicht, hatte einen Gedankenfehler.

Du brauchst eine Prüfung ob das Feld leer ist, aber das ist so vielleicht zu lösen

=WENN(Oder(Istleer($B$1);Istleer($C18));"";WENN(UND(VERGLEICH($B$1;[_Projektliste.xlsm]Tabelle1!$A:$A;0);VERGLEICH($C18;[_Projektliste.xlsm]Tabelle1!$M:$M;0));"übergeben";"in Bearbeitung"))

Gruß

Helmut

Answer 3

Hallo Helmut,

recht Herzlichen Dank für Deine schnelle Zuarbeit.
Ich habe deinen Vorschlag bereits in meine Tabelle integriert und ich kann sagen es funktioniert.

Nun hat sich im Laufe der letzten Minuten noch eine drittes Kriterium dazu gesellt welches ebenfalls auf Anwesenheit geprüft werden soll.
Diese liegt jedoch in der zweiten Tabelle und beinhaltet folgenden Text "in Bearbeitung".
Die Formel soll also folgendes tun:

Prüfe in Tabelle2 ob in einer Zeile sich alle drei gesuchten Kriterien befinden.

Wie arbeite ich nun diesen Text in deine Formel?

Beste Grüße,

Kapa

Answer 4

Hallo,

da nähere Angaben fehlen, packe das 3.Kriteriom einfach bei den Abfragen dazu, also in die Oder- bzw. Und-Klammer.

Sonst ist die Sache etwas genauer zu erlätern

Gruß

Helmut

Answer 5

Hallo Helmut,

zum besseren Verständnis habe ich eine Mappe mit den beiden Tabellen als Muster erstellt.
Hier der Link:

http://www.file-upload.net/download-4644710/Statuskontrolle_--bergabe.xlsx.html

Zur Erläuterung meines Anliegens.

In der Tabelle1 findest Du 3 Spalten.
Die ersten beiden bilden das Suchkriterium (Auftrags-Nr. und PSP-Element) nach dem in der Tabelle2 gesucht werden soll.
Sind beide Kriterien gefunden und ist das dritte Kriterium in der Tabelle2, Status "in Bearbeitung" auch erfüllt dann soll dieser Status in die Tabelle1, 3 Spalte (Status) eingeschrieben werden.

Ich hoffe es ist soweit verständlich beschrieben.
Falls nicht, einfach melden.

Vielen Dank und Grüße,

Kapa

Answer 6

Hallo Kapa,

hier mal mein Lösungsvorschlag (ich hoffe, ich habe dich richtig verstanden):

=WENN(SUMMENPRODUKT((Tabelle2!$A$4:$A$15=Tabelle1!$A$4)*(Tabelle2!$B$4:$B$15=Tabelle1!B7)*(Tabelle2!$C$4:$C$15="in Bearbeitung"))=1;"in Bearbeitung";"Übergeben")

Gruß

M.O.

Answer 7

Hallo M.O.;

-> funktioniert!!! :-)

vielen Dank für deine Unterstützung.

Habe die Formel nur noch ein wenig an die Umgebung angepasst.

Frage:

Warum Summenprodukt(.....)=1 als Probe und nicht Vergleich oder Index?

Möchte es für kommende Aufgaben verstehen.

Viele Grüße,

Kapa

Answer 8

Hallo Kapa,

mit Summenprodukt ist die Abfrage einfacher und du kannst die Abfragekriterien leicht ausbauen :-).

In den einzelnen Klammern wird die Matrix mit dem Suchkriterium verglichen. Wird eine Übereinstimmung gefunden, dann ergibt die Klammer 1 (= wahr) ansonsten 0 (= falsch). Ist also eine Bedingung nicht erfüllt, so wird durch die Multiplikation der einzelnen Klammern das Ergebnis 0.
Da deine Abfragekriterien nur einmal in der Suchmatrix (Tabelle 2) vorkommen, ist - wenn alle Abfragekriterien erfüllt sind - das Ergebnis 1. Daher die Abfrage, ob die Summenproduktformel = 1 ist.
(Sollte es möglich sein, dass alle Abfragekriterien mehfach zutreffen können, so müsste die Prüfung >0 heißen.)

Du kannst auch mal z.B. hier nachlesen: SUMMENPRODUKT

Gruß

M.O.

Answer 9

Hallo Kapa,

noch mal ich :-)
.
Ab Excel 2007 funktioniert auch diese Formel:

=WENN(ZÄHLENWENNS(Tabelle2!$A$4:$A$15;$A$4;Tabelle2!$B$4:$B$15;B4;Tabelle2!$C$4:$C$15;"in Bearbeitung")=1;"in Bearbeitung";"übergeben")

Funktioniert im Prinzip gleich wie die Summenproduktformel.

Gruß

M.O.

Answer 10

Hallo M.O.,

nochmals vielen Dank für die theoretische Beleuchtung.
Mit Hilfe deiner Erläuterung konnte ich selbständig die Formel an die Umgebung anpassen und weiter ausbauen.

Beste Grüße,

Kapa