Formeln nicht umschreiben wenn Tabellenblatt fehlt?

Question

Hallo Forumgemeinde,

hab mal wieder ein Excel Problemchen:

Wie kriege ich Excel dazu das er mir meine Formeln nicht umschreibt wenn der Bezug fehlt?

Folgende Problematik:
Habe ein Worksheet das normalerweise 1 Übersichtseite die mit Formeln geladen ist ,
sowie 12 Datensheets (die eben die Daten enthalten) - Monatsblätter!

So nun mein Problem,
Eine Beispielformel in der Übersichtseite sieht folgendermaßen aus:
=WENN($E5="";"";SVERWEIS($B5;'NEU FORM (9)'!$CQ:$DD;9;FALSCH))

lösche ich jetzt das Arbeitsblatt "NEU FORM (9)

sieht die Formel so aus:
=WENN($E5="";"";SVERWEIS($B5;#BEZUG!$CQ:$DD;4;FALSCH))

Kann ich das irgendie vermeiden das wenn das bezugsnehmede Arbeitsblatt nicht vorhanden ist, die Formel so drin bleibt wie Sie ist ?
Oder vor die Formel eine Prüfung setzen - wenn Arbeitsblatt vorhanden dann formel ausführen wenn nicht dann Formel ignorieren !!

Danke für eure Hilfe
Gruß Volker

Answer 1

Hallo,

wäre z.B. so zu lösen:

=WENN($E5="";"";Wenn(Istfehler( SVERWEIS($B5;'NEU FORM (9)'!$CQ:$DD;9;FALSCH)); "hier dein Text z.B. Blatt fehlt"; SVERWEIS($B5;'NEU FORM (9)'!$CQ:$DD;9;FALSCH)))

Gruß

Helmut

Answer 2

Hallo Volker,

die Angabe Deiner Excelversion fehlt.

Ab Excel 2007 funktioniert auch folgende Formel

=WENNFEHLER(SVERWEIS($B5;'NEU FORM (9)'!$CQ:$DD;9;FALSCH);"Arbeitsblatt fehlt")

Gruß
Rainer

Answer 3

Ja hab ja so ne ähnliche Formel im Datenblatt


=WENN(ISTFEHLER(SVERWEIS($B5;'NEU FORM (9)'!$CQ:$DD;3;FALSCH));"";SVERWEIS($B5;'NEU FORM (9)'!$CQ:$DD;3;FALSCH))

und es kommt aber bei Löschen des Blattes:

=WENN(ISTFEHLER(SVERWEIS($B5;#BEZUG!$CQ:$DD;3;FALSCH));"";SVERWEIS($B5;#BEZUG!$CQ:$DD;3;FALSCH))

Also dieses dämliche #Bezug wird immer noch gesetzt !

Ecxel Version ist Excel 2003

Answer 4

Hallo Volker,

dann kann ich mir das nur so vorstellen.

=WENN(ISTFEHLER(SVERWEIS($B5;INDIREKT("'NEU FORM (9)'!CQ:DD");3;FALSCH));"Arbeitsblatt fehlt";SVERWEIS($B5;INDIREKT("'NEU FORM (9)'!CQ:DD");3;FALSCH))

Gruß
Rainer

Answer 5

Funktioniert hervorragend ;-)

Danke
MFG
Volker