relativer Dateibezug

Question

Hallo,

ich habe eine Formel, die auf das Arbeitsblatt "Jan" zurückgreift:

=WENNFEHLER(INDEX(Jan!$B:$B;KKLEINSTE(WENN(NICHT(ISTFEHLER(SUCHEN("*"&$B$2&"*";Jan!$A$2:$F$800)));ZEILE(Jan!$2:$800));ZEILE(C1)));"")

Ich möchte den Namen des Arbeitsblattes "Jan" gern über das Feld E2 variabel halten, so dass sich die Formel automatisch anpasst, wenn das Feld E2=Feb ist usw. Geht das? Wie müßte die Formel dann aussehen?

Answer 1

Hallo Andreas!

Versuche es mal mit ungetesteter Formel:

=WENNFEHLER(INDEX(INDIREKT(E2&"!$B:$B");KKLEINSTE(WENN(NICHT(ISTFEHLER(SUCHEN("*"&$B$2&"*";INDIREKT(E2&"!$A$2:$F$800"))));ZEILE(INDIREKT(E2&"!$2:$800")));ZEILE(C1)));"")

MfG,
Oliver
[sub]Da hier der einzige Lohn für die Helfer eine Rückmeldung ist, wäre es nett, wenn Du[/sub]
[sup] ein Feedback abgeben könntest, ob der Lösungsvorschlag Dein Problem gelöst hat.[/sup]

Answer 2

Hi,

mit Formeln kenne ich mich nicht so gut aus, deshalb mal eine Verständnisfrage:

alle Tabellen besitzen die selbe Zeilenanzahl. Folglich könnte man doch in dem Ausdruck ZEILE(INDIREKT(E2&"!$2:$800")) m.E. auf den INDIREKT-Bezug bzw. auf den Bezug auf ein Tabellenblatt überhaupt verzichten: ZEILE($2:$800) sollte eigentlich ausreichen, da man damit nur einen Matrixbereich definieren will, so wie ich das verstehe - oder sehe ich das falsch?

Bis später,
Karin

Answer 3

Hallo Karin,

die Formel bezieht ihre Daten aus unterschiedlichen Tabellenblättern, je Monat ein Tabellenblatt mit dem entsprechenden Monatsnamen. Die dateistruktur ist in allen Monaten gleich, es ändert sich also nur der Name des Tabellenblattes und die entsprechenden Inhalte.
Ich möchte quasi in einer Gesamtübersicht duch click auf einen Monatsnamen die Berechnung für diesen speziellen Monat durchführen.
Gruß
Andreas

Answer 4

Hallo Oliver,

hab die Formel mal getestet. Obwohl sie eigentlich "richtig" aussieht bringt sie einen #BEZUG!-Fehler.
Gruß
Andreas

Answer 5

Hi Andreas,

das ist mir schon klar, aber an der von mir genannten Stelle in der Formel spielt es doch keine Rolle, von welchem Tabellenblatt die Matrix 2.3.4.5....800 genommen wird, da sie ja in allen Tabellenblättern identisch ist. Mache doch einfach mal folgendes: markiere in Olivers Formel den Ausdruck ZEILE(INDIREKT(E2&"!$2:$800")) und drücke F9 - es wird angezeigt 2.3.4.5...800. Wenn du nun stattdessen schreibst ZEILE($2:$800) oder wie in deiner Ausgangsformel ZEILE(Jan!$2:$800) und wiederum den Ausdruck mit F9 überprüfst, steht erneut 2.3.4.5...800 darin. Folglich spielt es keine Rolle, ob da ein Tabellenname vor der Zeilenmatrix steht oder nicht. Das würde die Formel halt einfach nur vereinfachen, nichts jedoch am Prinzip bzw. dem Ergebnis ändern.

Bis später,
Karin

Answer 6

Hallo Oliver,

sorry, hatte noch einen kleinen Fehler bei mir. Deine Formel ist ok und funktioniert prima!!! Vielen Dank an dich und Karin!!!
Andreas