email-Versand mit Fonts

Question

Hallo,

möchte bei einem E-Mail-Versand über Outlook in der email den Fonts "Calibri" einstellen. Habe dazu folgenden Code der zwar keinen Fehler verursacht aber ohne Wirkung bleibt...

......
With Application.DefaultWebOptions _
.Fonts(msoCharacterSetEnglishWesternEuropeanOtherLatinScript)
.FixedWidthFont = "Calibri"
.FixedWidthFontSize = 11
End With
.......
Weiß jemand Rat?
Gruß
Andreas

Answer 1

Hallo Andreas!

Ich weiß jetzt nicht, wie Dein gesamter Code aussieht. Nur Codeschnipsel hier aufzuführen hilft nicht sehr weiter. Wenn ich mal davon ausgehe, dass es um das Makro von vor ein paar Tagen geht, dann geht das anders. Du musst in der HTML-Nachricht diese Einstellungen als html-Befehle mitgeben. Die Zeile

.HTMLBody = "Testnachricht" & strSignatur

sieht dann so aus

.HTMLBody = "<p><font face=""Calibri"" size=""2"">Testnachricht</font></p>" _
& strSignatur

Hier nochmal Dein Makro aus Deinem Beitrag https://supportnet.de/t/2457532 mit der entsprechend geänderten Zeile.

Sub Mail_senden_mit_Signatur()
Dim strSignatur As String
Dim oApp As Object
Dim oMail As Object

Set oApp = CreateObject("OUTLOOK.Application")
Set oMail = oApp.CreateItem(0)

With oMail
.To = "Mail@web.de" 'Empfänger
.cc = "" 'Kopie
.bcc = "" 'Blindkopie
.Subject = "Testbetreff" 'Betreff
.GetInspector.Display 'Signatur anzeigen
Set .SendUsingAccount = .Session.Accounts.Item(2) 'Die Zahl in der Klammer ist das Sendekonto
strSignatur = .HTMLBody 'Signatur zwischenspeichern
.HTMLBody = "<p><font face=""Calibri"" size=""2"">Testnachricht</font></p>" _
& strSignatur 'E-Mailnachricht mit Schriftart Calibri und Signatur
'.Send
.Display
End With

Set oApp = Nothing
Set oMail = Nothing
End Sub

MfG,
Oliver
[sub]Da hier der einzige Lohn für die Helfer eine Rückmeldung ist, wäre es nett, wenn Du[/sub]
[sup] ein Feedback abgeben könntest, ob der Lösungsvorschlag Dein Problem gelöst hat.[/sub]

Answer 2

Hallo Oliver,

Genau, die Frage bezieht sich auf den Code, den wir vor ein paar Tagen besprochen hatten. Insofern passt
deine Antwort genau!
Wie immer vielen Dank!,,,
Gruß Andreas

P.S. Du kennst dich ja super auch mit Outlook aus. Ich kriege einfach keinen Tipp auf meine Anfrage
dazu. "übermittlungsfehler wegen fehlerhafter Feeds...." Damit werden Kalender und Kontakte nicht
synchronisiert. Hast du da eine Idee woran das liegen könnte? Ich habe eigentlich gar keine Feeds
abonniert.

Answer 3

Hallo Andreas!

Wenn Du anstelle eines festen Textes als Nachricht eine Variable benutzen möchtest, dann sieht der Code wie folgt aus:

Sub Mail_senden_mit_Signatur()
Dim strSignatur As String
Dim oApp As Object
Dim oMail As Object
Dim sBody As String

Set oApp = CreateObject("OUTLOOK.Application")
Set oMail = oApp.CreateItem(0)

sBody = "Testnachricht"

With oMail
.To = "Mail@web.de" 'Empfänger
.cc = "" 'Kopie
.bcc = "" 'Blindkopie
.Subject = "Testbetreff" 'Betreff
.GetInspector.Display 'Signatur anzeigen
Set .SendUsingAccount = .Session.Accounts.Item(2) 'Die Zahl in der Klammer ist das Sendekonto
strSignatur = .HTMLBody 'Signatur zwischenspeichern
.HTMLBody = "<p><font face=""Calibri"" size=""2"">" & sBody & "</font></p>" _
& strSignatur 'E-Mailnachricht mit Schriftart Calibri und Signatur
'.Send
.Display
End With

Set oApp = Nothing
Set oMail = Nothing
End Sub

Bitte versuche nächstes mal einen Beitrag nicht über den Pager weiter fortzuführen. Fragen gehören in das Forum, private Nachrichten in den Pager.

Bei Fragen melde Dich.

MfG,
Oliver
[sub]Da hier der einzige Lohn für die Helfer eine Rückmeldung ist, wäre es nett, wenn Du[/sub]
[sup] ein Feedback abgeben könntest, ob der Lösungsvorschlag Dein Problem gelöst hat.[/sup]

Answer 4

..geht klar, vielen Dank!
Andreas