Frage stellen

Excel Formel "Zählenwenn" hilfe

2.3k Aufrufe
Gefragt in Tabellenkalkulation von
Hallo,

folgende Aufgabenstellung:

Es soll gezählt werden

wenn in A5:A30 ein beliebiger Wert drin steht

und

in B5:B30 die Zahl 13.

Das ganze sollte dann von insgesamt 12 Blättern in eine Arbeitsmappe gezählt werden.

Bitte um Hilfe!
Danke

6 Antworten

0 Punkte
Beantwortet von hajo_zi Experte (9.1k Punkte)
Zähle es auf jeder Tabelle einzeln ZählenwennS()
und dann Summe über alle Tabellen.

Gesamtsumme aus Summen über mehrere Tabellen
probiers mal mit
=SUMME(Tabelle1:Tabelle31!E4:F4)
Die Namen "Tabelle1:Tabelle31" musst ‚Du natürlich in Deine Namen ändern!
wobei immer die erste und die letzte Tabelle angegeben werden.
Dabei ist zu beachten, dass zwischen der Tabelle1 und Tabelle 31, kein anderes Tabellenblatt dazwischen liegen darf, welches nicht in die Berechnung mit aufgenommen werden soll. Diese Tabellenblätter sollten dann vor "Tabelle1" oder hinter "Tabelle31" verschoben werden

Gruß Hajo
0 Punkte
Beantwortet von
Also als Primärziel steht:
zählen wenn in

A5:A30 ein Wert zwischen 1 und 100 drin steht

und

B5:B30 die Zahl 13

und

C5:C30 ein Datum ohne Tag (**.01.2014)
(also **.02.2014 soll dann nicht gezählt werden)



hier hängt es allerdings:

Zähle es auf jeder Tabelle einzeln ZählenwennS()
und dann Summe über alle Tabellen.


ich hatte mit
=ZÄHLENWENNS(A5:A30;”*”;B5:B30;”13”)
angefangen aber das hat nicht geklappt, da kommt immer 0 raus!
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo,

probier's mal mit folgender Matrixformel.

=SUMME(ZÄHLENWENNS(INDIREKT("Tabelle"&ZEILE(1:12)&"!A:A");">="&1;INDIREKT("Tabelle"&ZEILE(1:12)&"!A:A");"<="&100;INDIREKT("Tabelle"&ZEILE(1:12)&"!B:B");13))

Die Arbeitsblätter haben die Namen "Tabelle1" bis "Tabelle12"

Allerdings musst Du das Kriterium für Spalte C noch hinzufügen, da ich das mit dem Datum ohne Tag nicht verstehe.

Gruß
Rainer
0 Punkte
Beantwortet von
danke,

wenn ich z.b. in 20 Zeilen ein Datum habe:

20.01.2014
13.01.2014
02.03.2014
03.01.2014
....

Soll er den Monat März nicht Zählen....

Januar allerdings schon!
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo,

die Formel für die Zählung im Einzelblatt könnte so aussehen:

=SUMMENPRODUKT((A5:A30>=1)*(A5:A30<=100)*(B5:B30=13)*(MONAT(C5:C30)<>3))

Auf eine komplexe Formel für die Zählung über alle Blätter würde ich bei dieser Konstellation verzichten, denn sie wird erheblich komplizierter.

Gruß
Rainer
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo noch mal,

die einfachste Lösung mit einer komplexen Formel wäre, das Benutzen einer Hilfsspalte in den Einzelblättern.

Schreibe in D5 folgende Formel und ziehe sie bis D30 nach unten:

=MONAT(C5)

Nun zählt Dir folgende Matrixformel die Anzahl der vorgegebenen Kriterien aller 12 Arbeitsblätter.

=SUMME(ZÄHLENWENNS(INDIREKT("Tabelle"&ZEILE(1:12)&"!A5:A30");">=1";INDIREKT("Tabelle"&ZEILE(1:12)&"!A5:A30");"<=100";INDIREKT("Tabelle"&ZEILE(1:12)&"!B5:B30");13;INDIREKT("Tabelle"&ZEILE(1:12)&"!D5:D30");"<>3"))

Gruß
Rainer
...