Excel Tabellen formeln

Question

Hallo,

ich benutze diese WENN Formel und möchte gerne das aus einer anderen spalte ein Wert dazu gerechnet werden kann .

=WENN(UND(ODER(C5="Mo";C5="Di";C5="Mi";C5="Do";C5="Fr");(ODER(F5="F";F5="S";F5="N")));0,75;WENN(UND(ODER(C5="Mo";C5="Di";C5="Mi";C5="Do";C5="Fr");ODER(F5="";F5="A"));-7;WENN(UND(ODER(C5="Sa";C5="So");(ODER(F5="F";F5="S";F5="N")));9,75;WENN(UND(ODER(C5="Sa";C5="So");F5="A");0;WENN(UND(ODER(C5="Sa";C5="So");F5="U");7;0)))))

Meine Tabelle ist so aufgebaut:
B5 datum | C5 Wochentag | D5 WENN Funtion | E5 zahl | F5 Schicht (F/S/N)

zb. Wenn die WENN-Funktion den Wert -7 auswählt und in der Spalte (E5) steht 2, dann sollte in der Spalte (D5) -5 stehen

Ich bedanke mich jetzt schon für die hilfe, ich brauche nur die formel =)

Gruß Homann

Answer 1

Hallo,

wenn ich Dich richtig verstehe, müsste folgende Formel funktionieren.

=WENN(UND(WOCHENTAG(B5;2)<6;ODER(F5={"F"."S"."N"}));0,75;WENN(UND(WOCHENTAG(B5;2)<6;ODER(F5="";F5="A"));WENN(E5=2;-5;-7);WENN(UND(WOCHENTAG(B5;2)>5;ODER(F5={"F"."S"."N"}));9,75;WENN(UND(WOCHENTAG(B5;2)>5;F5="A");0;WENN(UND(WOCHENTAG(B5;2)>5;F5="U");7;0)))))

Gruß
Rainer

Answer 2

Hallo Rainer,

die Formel hat leider nicht funktioniert =(
er rechnet bzw, wählt nur die WENN funktion aus, wenn ich in der Spalte E5 eine Zahl schreibe rechnet er die nicht mit ...

vielleicht hast du noch ne idee

Answer 3

Hallo,

von Berechnen war in Deiner Frage nicht die Rede.

Wenn die WENN-Funktion den Wert -7 auswählt und in der Spalte (E5) steht 2, dann sollte in der Spalte (D5) -5 stehen

=WENN(UND(WOCHENTAG(B5;2)<6;ODER(F5={"F"."S"."N"}));0,75;WENN(UND(WOCHENTAG(B5;2)<6;ODER(F5="";F5="A"));WENN(ISTZAHL(E5);-7+E5;-7);WENN(UND(WOCHENTAG(B5;2)>5;ODER(F5={"F"."S"."N"}));9,75;WENN(UND(WOCHENTAG(B5;2)>5;F5="A");0;WENN(UND(WOCHENTAG(B5;2)>5;F5="U");7;0)))))

Gruß
Rainer

Answer 4

hallo rainer,

die formel funktioniert nur wenn ich in spalte F5 "A" eintrage dann rechnet er die Zahl in spalte E5 mit, aber für die anderen "S" "F" "N" "U" passiert wieder nichts =(...

kannst du noch mal rüberschauen ;)

Gruß und vielen Dank

Homann

Answer 5

Hallo Rainer

ich habs rausgefunden:

=WENN(UND(ODER(C5="Mo";C5="Di";C5="Mi";C5="Do";C5="Fr");(ODER(F5="F";F5="S";F5="N")));0,75;WENN(UND(ODER(C5="Mo";C5="Di";C5="Mi";C5="Do";C5="Fr");ODER(F5="";F5="A"));-7;WENN(UND(ODER(C5="Sa";C5="So");(ODER(F5="F";F5="S";F5="N")));9,75;WENN(UND(ODER(C5="Sa";C5="So");F5="A");0;WENN(UND(ODER(C5="Sa";C5="So");F5="U");7;0)))))+SUMME(E5)
[u]

ganz einfach +SUMME(E5) musste ich nur ranhängen ...

Gruß Marcel

Answer 6

Hallo Marcel,

bei weiteren Fragen bitte zweifelsfreie Erläuterungen des Problems, denn der Helfer kennt weder Deine Gedankengänge noch sieht er Deine Datei!!!

Gruß
Rainer

Answer 7

Hallo Marcel,

auch Deine letzte Formel lässt sich noch optimieren.

In folgender Form bringt sie das gleiche Ergebnis und hat 86 Zeichen weniger.

=WENN(UND(WOCHENTAG(B5;2)<6;ODER(F5={"F"."S"."N"}));0,75;WENN(UND(WOCHENTAG(B5;2)<6;ODER(F5={""."A"}));-7;WENN(UND(WOCHENTAG(B5;2)>5;(ODER(F5={"F"."S"."N"})));9,75;WENN(UND(WOCHENTAG(B5;2)>5;F5="A");0;WENN(UND(WOCHENTAG(B5;2)>5;F5="U");7;0)))))+E5

Gruß
Rainer