2.4k Aufrufe
Gefragt in Tabellenkalkulation von florian1010 Mitglied (754 Punkte)
Hallo Zusammen,

momentan sehe ich gerade den Wald vor lauter Bäumen nicht mehr. Deshalb bitte ich um eure Hilfe.

Ich habe eine Excel 2010-Ausgangsdatei (C:\Gesamt) und eine Excel 2010-Zieldatei (C:\Bestand).

In der Ausgangsdatei sind alle möglichen Namen und die passenden Daten drin. In Spalte A stehen fortlaufende Nummern.

Ich möchte nun in der Zieldatei (beginnt in Spalte A11) nur die Daten anzeigen lassen, die einen bestimmten Namen haben. Die Abfrage soll nun zum Ergebnis führen, dass wenn in der Ausgangsdatei in Spalte B "Michael" steht und die Spalte D nicht leer ist, in der Zieldatei die Inhalte aus Spalte A bis D und G bis J angezeigt werden sollen. Jedoch ohne Leerzeilen.

Ich hab es bereits mit Index versucht, aber leider nicht zum laufen gebracht. Die einzelnen Spalten hätte ich dann mit Sverweis gemacht.

{=WENNFEHLER(INDEX('[GESAMT.xlsm]Übersicht'!A:A;KKLEINSTE(WENN(('[GESAMT.xlsm]Übersicht'!B$1:B$99="Michael")+('GESAMT.xlsm]Übersicht'!D$1:D$99<>"");ZEILE('[GESAMT.xlsm]Übersicht'!$1:$99));ZEILE('GESAMT.xlsm]Übersicht'!A2)));"")}


Vielen Dank schon mal für eure Hilfe.

Gruß
Florian

7 Antworten

0 Punkte
Beantwortet von m-o Profi (22.7k Punkte)
Hallo Florian,

versuch es mal statt
INDEX('[GESAMT.xlsm]Übersicht'!A:A...
mit
INDEX('[GESAMT.xlsm]Übersicht'!$A$1:$A§99

außerdem fehlen in der Formel teilweise die eckigen Klammern vor dem Arbeitsmappennamen. Auch würde ich alle Bezüge absolut gestalten.
Deine neue Formel sollte also so aussehen (ungetestet):

{=WENNFEHLER(INDEX('[GESAMT.xlsm]Übersicht'!$A$1:$A$99;KKLEINSTE(WENN(('[GESAMT.xlsm]Übersicht'!$B$1:$B$99="Michael")+('[GESAMT.xlsm]Übersicht'!$D$1:$D$99<>"");ZEILE('[GESAMT.xlsm]Übersicht'!$1:$99));ZEILE('[GESAMT.xlsm]Übersicht'!A2)));"")}

Zu deinem Problem kannst du auch mal hier nachschauen: KLICK MICH!

Gruß

M.O.
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo Florian,

leider kann man deine Formel ohne Beispielmappe nicht testen und zum Nachbau habe ich keine Lust.

Nur so viel:
Die Funktion ZEILE() benötigt weder Arbeitsmappen- noch Arbeitsblattnamen.

Teste mal damit

=WENNFEHLER(INDEX([GESAMT.xlsm]Übersicht!$A$1:$A$99;KKLEINSTE(WENN(([GESAMT.xlsm]Übersicht!$B$1:$B$99="Michael")+([GESAMT.xlsm]Übersicht!$D$1:$D$99<>"");ZEILE($1:$99));ZEILE(A2)));"")
0 Punkte
Beantwortet von florian1010 Mitglied (754 Punkte)
Hallo M.O., hallo rainberg,

warum auch immer, ignoriert mir die Formel den Teil, in dem es heißt, nur beschriebene Zellen aus Spalte D verwenden.

Zudem habe ich die Auswahl Variabel in Zelle B6 im Sheet Bestand eingebaut. Eigentlich sollte es mir nur alle aus der Abteilung Fußball anzeigen, bei denen ein Vorname in Spalte D eingetragen ist.

Das Beispiel hab ich es etwas vereinfacht, indem ich alles in eine Datei geschrieben habe.

Beispieldatei Index

Vielen Dank schon mal noch

Gruß
Florian
0 Punkte
Beantwortet von m-o Profi (22.7k Punkte)
Hallo Florian,

versuch mal für die Zelle A11 in der Tabelle Bestand die folgende Matrix-Formel:

{=WENN(ZEILE(Z1)>SUMME((Übersicht!$B$1:$B$99=Bestand!$B$6)*(Übersicht!$D$1:$D$99<>""));"";INDEX(Übersicht!A:A;KKLEINSTE(WENN((Übersicht!$B$1:$B$99=Bestand!$B$6)*(Übersicht!$D$1:$D$99<>"");ZEILE($1:$99));ZEILE(Z1))))}

Die anderen Daten würde ich dann einfach mit SVERWEIS auslesen:
Beispiel für B11 -Abteilung- : =WENNFEHLER(SVERWEIS(A11;Übersicht!$A$2:$B$99;2;FALSCH);"")

Gruß

M.O.
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo Florian,

sorry, dass ich eine Beispielmappe angemahnt und nun nicht geantwortet habe.

Der Grund:
Wegen schlechter Erfahrungen mit dem von dir gewählten Filehoster. lade ich von diesem keine Dateien mehr herunter.
Das hatte ich hier schon mehrfach bekannt gegeben.

Gruß
Rainer
0 Punkte
Beantwortet von florian1010 Mitglied (754 Punkte)
Hallo M.O.,

vielen Dank. Jetzt hat's einwandfrei funktioniert. Auf Summe einzubauen wäre ich tatsächlich nie gekommen. Klasse.

@Rainer: Sorry, ich hab es leider nicht mitbekommen, dass du von diesem Filehoster keine Dateien mehr runter lädst. Kannst du mir einen besseren/sichereren empfehlen?

Gruß
Florian
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo Florian,

ich bevorzuge die Dropbox und alternativ diesen Hoster

Gruß
Rainer
...