Makro PDF erstellen

Question

Hallo,
ich verwende zur Zeit dieses Makro und habe dabei folgende Probleme:
1. Im PDF des 2. Tabellenblatts (Aktionsplanung_Vol) werden nur die ersten 3 Zeilen gedruckt, obwohl mehr Zeilen Inhalt haben

2. Im PDF des 3. Tabellenblatts (Aktionsplanung_Fam) werden nur die ersten 2 Zeilen gedruckt, obwohl mehr Zeilen Inhalt haben

3. Im 4. PDF klappt alles.

Schön wäre auch noch, wenn die Dateinamen wie folgt heißen würden:
2. Tabellenblatt: Aktionsplanung_Vol_Datum_Zelle A2
3. Tabellenblatt: Aktionsplanung_Fam_Datum_Zelle A2
4. Tabellenblatt: Aktionsplanung_67_Datum_Zelle A2

Sub PDF_drucken()
'
' PDF_drucken Makro
'

'
Range("A1:P2").Select
Range(Selection, Selection.End(xlDown)).Select
Range(Selection, Selection.End(xlDown)).Select
Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
"G:\Einkauf\Werbung\Aktionsplanungen PDF\Aktionsplanung_Vol_.pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True
Range("A1:P2").Select
Range(Selection, Selection.End(xlDown)).Select
Range(Selection, Selection.End(xlDown)).Select
Range("B13").Select
Sheets("Aktionsplanung_Fam").Select
Range("A1:I2").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
"G:\Einkauf\Werbung\Aktionsplanungen PDF\Aktionsplanung_Fam_.pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True
Sheets("Aktionsplanung_67").Select
Range("A1:F2").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
"G:\Einkauf\Werbung\Aktionsplanungen PDF\Aktionsplanung_67_.pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True
Range("B14").Select
Sheets("Aktionsplanung_Vol").Select
End Sub

Answer 1

Hallo,

ich habe die exceldatei hier hochgeladen: http://www43.zippyshare.com/v/8dVmj0TJ/file.html


gruß,
colatrinkerin

Answer 2

Hallo,

probier mal den folgenden Code:

Sub PDF_drucken()
'
' PDF_drucken Makro

Dim strPfad As String
Dim lngLetzte As Long

'Pfad und Dateiname für das Blatt Aktionsplanung_Vol werden festgelegt
strPfad = "G:\Einkauf\Werbung\Aktionsplanungen PDF\Aktionsplanung_Vol_" & Date & "_" & Worksheets("Aktionsplanung_Vol").Range("A2").Value
strPfad = "C:\Test\Aktionsplanung_Vol_" & Date & "_" & Worksheets("Aktionsplanung_Vol").Range("A2").Value

'letzte beschriebene Zeile im Tabellenblatt in Spalte A ermitteln
lngLetzte = Worksheets("Aktionsplanung_Vol").Cells(Rows.Count, 1).End(xlUp).Row
'ausgefüllter Bereich aus Tabellenblatt wird gedruckt
With Worksheets("Aktionsplanung_Vol").Range("A1:P" & lngLetzte)
.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPfad, Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End With

'das zweite Blatt
strPfad = "G:\Einkauf\Werbung\Aktionsplanungen PDF\Aktionsplanung_Fam_" & Date & "_" & Worksheets("Aktionsplanung_Fam").Range("A2").Value
strPfad = "C:\Test\Aktionsplanung_Fam_" & Date & "_" & Worksheets("Aktionsplanung_Vol").Range("A2").Value

lngLetzte = Worksheets("Aktionsplanung_Fam").Cells(Rows.Count, 1).End(xlUp).Row

With Worksheets("Aktionsplanung_Fam").Range("A1:I" & lngLetzte)
.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPfad, Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End With

'das dritte Blatt
strPfad = "G:\Einkauf\Werbung\Aktionsplanungen PDF\Aktionsplanung_67_" & Date & "_" & Worksheets("Aktionsplanung_67").Range("A2").Value
strPfad = "C:\Test\Aktionsplanung_67_" & Date & "_" & Worksheets("Aktionsplanung_Vol").Range("A2").Value

lngLetzte = Worksheets("Aktionsplanung_67").Cells(Rows.Count, 1).End(xlUp).Row

With Worksheets("Aktionsplanung_67").Range("A1:F" & lngLetzte)
.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPfad, Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End With

End Sub

Gruß

M.O.

Answer 3

Hallo,

ich habe den Code hinterlegt.

An dieser Stelle hakt der Code:
.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPfad, Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=True

Answer 4

Hallo,

ich hatte im Code noch den Pfad für mein Testverzeichnis hinterlegt und beim posten nicht rausgelöscht ;-(.

Lösche alle Zeilen mit

strPfad = "C:\Test\Aktionsplanung_Vol_" & Date & "_" & Worksheets("Aktionsplanung_Vol").Range("A2").Value

dann sollte es funktionieren.

Gruß

M.O.

Answer 5

ach mensch....da hätte ich aber auch nun selbst drauf kommen können.

Vielen herzlichen Dank - das klappt jetzt wie geschmiert :-)