4.7k Aufrufe
Gefragt in Tabellenkalkulation von
Hi Leute,

OK, jetzt steh ich auch mal auf dem Schlauch. Ich habe folgende Formel die super funktioniert.

=SUMMENPRODUKT((ISTZAHL($A$3:$A$2394))*(LÄNGE($A$3:$A$2394)=5)*(LINKS($A$3:$A$2394;2)=TEXT($A2398;"@"))*K$3:K$2394)

Wie muss ich die umbauen, damit sie nur die gefilterten bzw. nicht manuell ausgeblendeten Zeilen summiert? Jemand eine Idee?

Danke für Eure Hilfe

6 Antworten

0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo xlKing,

ich kann nur vermuten, dass ich mit meiner Formel richtig liege, da ich
nicht im Besitz der entsprechenden Testumgebung bin.

Teste mal selbst.

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("K"&ZEILE($3:$239
4)))*(ISTZAHL($A$3:$A$2394))*(LÄNGE($A$3:$A$2394)=5)*
(LINKS(A$3:A$2394;2)=TEXT($A2398;"@")))

Gruß
Rainer
0 Punkte
Beantwortet von
Hallo Rainer,

sieht auf den ersten Blick gut aus. Vielen Dank schon mal. Kanns aber leider erst morgen testen, da ich grad keinen Zugriff auf die Datei habe.

Meld mich dazu nochmal - Mr. K.
0 Punkte
Beantwortet von
Hallo Rainer,

noch kurz mein Feedback hierzu.
Habs grad getestet. Funktioniert wunderbar. Genial wie immer :-)

Allerdings bin ich kein Freund von fixen Adressangaben. Einmal Spalte einfügen oder löschen und schon stimmt die Formel nicht mehr. Habe das daher wie folgt erweitert. Dadurch lässt sich die Formel dann auch nach rechts kopieren.

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT(TEIL(ZELLE("adresse";K$1);2;FINDEN("$";ZELLE("adresse";K$1);2)-2)&ZEILE($3:$239
4)))*(ISTZAHL($A$3:$A$2394))*(LÄNGE($A$3:$A$2394)=5)*
(LINKS(A$3:A$2394;2)=TEXT($A2398;"@")))

Nochmal vielen Dank für die Lösung.
Grüße - Mr. K.
0 Punkte
Beantwortet von rainberg Profi (14.9k Punkte)
Hallo xlKing,

das ist natürlich eine gute Lösung für einen Excelfreak.

Allerdings fragt sich, ob sich ein wenig geübter Excelanwender damit anfreunden kann?
Die selben Befürchtungen hatte ich eigentlich schon bei meiner Formel, welche durch deinen Zusatz noch weiter kompliziert wird.

Gruß
Rainer
0 Punkte
Beantwortet von
Hallo Rainer,

da hast du natürlich Recht. Das ist ein wahres Monstrum geworden. Aber sind es nicht grade die komplexen Formeln, die
besonders viel Spaß machen, wenn sie dann auch noch funktionieren? :-)

Vereinfacht kann man die Formel natürlich auch so ausdrücken in dem man nur die 2 wichtigsten Parameter setzt.
=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("K"&ZEILE($3:$10)))*(ISTZAHL($A$3:$A10)))

Ich habe dann lediglich die drei Zeichen "K" durch eine Teilformel ersetzt, welche den Spaltennamen aus der Zelle ausliest, in
der die Formel steht, damit diese sich kopieren lässt. Diese Teilformel lautet:
TEIL(ZELLE("adresse";K$1);2;FINDEN("$";ZELLE("adresse";K$1);2)-2)

Bei einer SVERWEIS-Formel ist das natürlich einfacher. Da braucht man, statt der fixen Spaltennr. in Parameter 3 lediglich
SPALTE() anzugeben um Fehlern durch das Einfügen zusätzlicher Spalten vorzubeugen.

So oder so, ist es jedenfalls wieder mal eine erstklassige Formel von dir, die perfekt funktioniert. Zumindest wenn irgendein
Filter aktiv ist.

Gruß Mr. K.
0 Punkte
Beantwortet von
hilfe ich hänge da auch fest ich habe die Formel

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("D"&ZEILE(101:1195)))*(B101:B1195="geprüft"))

mein Problem ich kann die Formel nicht zeihen weder nach rechts noch nach unten?

Ich bräuchte den Teil -- ("D"&ZEILE(101:1195))) irgendwie dynamisch, bloß wie?

habe versucht das von euch nachzubauen, aber keine Chance

für Tipps wäre ich sehr dankbar

gruß

Marcus
...