71 Aufrufe
Gefragt in Tabellenkalkulation von
Hallo Alle

Ich will in einer Excel Datei die Summe aus verschiedenen Tabellenblätter für definierte Suchbegriffe bilden.

Dazu verwende ich die nachstehende Formel
=SUMMEWENNS(indirekt('Ende Januar 21:Ende Dezember 21'! (C4:C30;A4:A30;A10;B4:B30;B10)))
Ich erhalte immer den Fehler "Sie haben zu wenig Argumente für diese Funktion eingegeben"

In Spalte "C" stehen die Beträge in Dollar, In Spalte "A" ist der erste Teil des Suchbegriffs welcher in Zelle A10 definiert wird, in der Spalte "B" ist der zweite Teil des Suchbegriffs welcher in Zelle B10 definiert wird.

Was mach ich falsch?
Besten Dank für eure Unterstützung
Gruss Heinz

2 Antworten

0 Punkte
Beantwortet von m-o Profi (20.2k Punkte)
Hallo Heinz,

abgesehen davon, dass am Ende der Aufzählung eine schließende Klammer fehlt, stimmt auch die Syntax nicht.

Wenn du mit Indirekt arbeitest musst du die einzelnen Teile mit einem &-Zeichen verbinden. Außerdem willst du ja die Bedingungen auch auf den Tabellenblättern prüfen. Daher musst du auch vor den einzelnen Spalten, in denen die Bedingungen geprüft werden sollen, auf die entsprechenden Tabellen verweisen.

Ich nehme mal an, dass du die Summe aus allen monatlichen Tabellenblättern summieren willst und nicht nur aus den Arbeitsblättern "Ende Januar 21" und "Ende Dezember 21". Das kannst du aber nicht über den Doppelpunkt lösen. Du musst alle Tabellenblätter aufführen.

Gehe wie folgt vor:

Schreibe den Namen aller Tabellenblätter, die aufsummieren willst untereinander in dein Tabellenblatt mit der Formel und weise dem Bereich dann z.B. den Namen "Blattnamen" zu (z.B. über das Menüband "Formeln" und "Namen definieren".

Dann ersetze deine Summewenns-Formel durch die folgende Formel:

=SUMMENPRODUKT((T(INDIREKT("'"&MTRANS(Blattnamen)&"'!A"&ZEILE(1:100)))=A4)*(T(INDIREKT("'"&MTRANS(Blattnamen)&"'!B"&ZEILE(1:100)))=B4)*(N(INDIREKT("'"&MTRANS(Blattnamen)&"'!C"&ZEILE(1:100)))))

Da es sich um eine Matrix-Formel handelt, schließe die Eingaben mit STRG+UMSCHALT+RETURN ab. Danach müsste die Formel dann so aussehen:

{=SUMMENPRODUKT((T(INDIREKT("'"&MTRANS(Blattnamen)&"'!A"&ZEILE(1:100)))=A4)*(T(INDIREKT("'"&MTRANS(Blattnamen)&"'!B"&ZEILE(1:100)))=B4)*(N(INDIREKT("'"&MTRANS(Blattnamen)&"'!C"&ZEILE(1:100)))))}

Mit dem Teil ZEILE(1:100) legst du den Bereich der Zeilen fest, die aufsummiert werden sollen. Das musst du natürlich auf deine Verhältnisse anpassen. Dieser muss in der ganzen Formel gleich sein.

Gruß

M.O.
0 Punkte
Beantwortet von pause645 Mitglied (125 Punkte)
Hallo M.O.

Besten Dank für die Hilfe.
Das werde ich doch gleich ausprobieren.

Gruss Heinz
...