100 Aufrufe
Gefragt in Textverarbeitung von

Hallo,
mit der Zeile:

TablNr = AppWD.ActiveDocument.Tables.Count

kann ich die Anzahl der Tabellen in meinen Word Dokument ermittel.
Für mich wichtig wäre aber die Anzahl der Tabellen auf Blatt 1 oder Blatt 2.

Die Blattanzahl kann unterschiedlich sein.Hab schon gesucht und probiert, aber ich schaffe es nicht.
Hat jemand einen Tipp?

1 Antwort

0 Punkte
Beantwortet von m-o Profi (21.4k Punkte)

Hallo,

hier mal ein möglicher Lösungsansatz:

Sub tabellen_auf_seiten()

Dim tblDoc As Table
Dim intSeiten As Integer
Dim arrTabellen As Variant

'Bildschirmaktualisierung ausschalten:
Application.ScreenUpdating = False

'Anzahl der Seiten in Variable schreiben
intSeiten = ActiveDocument.ComputeStatistics(wdStatisticPages)

'Array für Seiten und Tabellen redimensionieren
ReDim arrTabellen(intSeiten)

'Alle Tabellen im aktiven Dokument durchlaufen
For Each tblDoc In ActiveDocument.Tables
  '1. Zelle in jeder auswählen
  tblDoc.Rows(1).Cells(1).Select
  'Zähler für die einzelnen Seiten erhöhen
  arrTabellen(Selection.Information(wdActiveEndPageNumber)) = arrTabellen(Selection.Information(wdActiveEndPageNumber)) + 1
Next tblDoc

'Bildschirmaktualisierung einschalten:
Application.ScreenUpdating = True

'Ausgabe
For intSeiten = 1 To UBound(arrTabellen)
  'prüfen, ob Feld leer = keine Tabellen
  If arrTabellen(intSeiten) = "" Then arrTabellen(intSeiten) = "keine"
  'Ausgabe in Messagebox
  MsgBox "Auf der Seite " & intSeiten & " befinden sich " & arrTabellen(intSeiten) & " Tabellen!", 64, "Anzahl Tabellen"
Next intSeiten

End Sub

Dabei werden aber alle Tabellen durchlaufen.

Gruß

M.O.

...