neue Zuordnung bei Doppelklick nach dem 3. DK anstatt 2 soll leer erscheinen

Question

Guten morgen an das Team vom Forum

Habe da nochmals eine Frage:

Besteht die Möglichkeit dieses VBA so zu verändern, das man anstatt Mod 2 als leer  erscheint und nach dem ersten Doppelklick erst eine 1 erscheint und beim nächsten Doppelklick die 2 und nach dem dritten Doppelklick wieder die leer erscheint?

Dies ist jetzt nur für die Zelle J3, müsste dies aber für die Zellen J2 bis K 68 erstellen. Gibt es hierfür auch eine Lösung oder muss man diesen Vorgang für jede Zelle wiederholen?

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

ActiveSheet.Unprotect

If Not Intersect(Target, Range("j3")) Is Nothing Then

Cancel = True

Range("j3") = Range("j3").Value Mod 2 + 1

End If

If Not Intersect(Target, Range("j3")) Is Nothing Then

End If

ActiveSheet.Protect

End Sub

Wäre ganz toll wenn mir jemand einen Vorschlag oder eine Lösung zukommen lassen würde.

Gruß Adde

Answer 1

Hi,

versuche es mal so:

If Not Intersect(Target, Range("J3:K68")) Is Nothing Then
    Cancel = True
    If Target = 2 Then
        Target.ClearContents
    Else
        Target = Target + 1
    End If
End If

Bis später, Karin

Answer 2

Hallo Adde,

ersetze das vorhanden Makro durch das folgende Makro im VBA-Projekt des betreffenden Arbeitsblattes:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

'Makro nur im Bereich J2 - K 68 ausführen
If Not Intersect(Target, Range("j2:k68")) Is Nothing Then
  'Blattschutz aufheben, falls vorhanden - falls kein Blattschutz, kann das entfallen
   ActiveSheet.Unprotect
  'nicht in Zelle klicken
  Cancel = True
  'neuen Inhalt der Zelle ermitteln
  Select Case Target.Value
    Case Is = "": Target.Value = 1
    Case Is = 1: Target.Value = 2
    Case Is = 2: Target.Value = ""
  End Select
  
  'Blattschutz wieder setzen
  ActiveSheet.Protect
  
End If

End Sub

Gruß

M.O.

P.S. Da war Karin schneller.

Answer 3

Hallo zusammen,

vielen lieben Dank Karin und M.O. für die Hilfe. Habe es umgesetzt und funktioniert.

Gruß Adde