Tabellenkalkulation

Hilfe bei verschachtelter WENN Formel

Diskussionsgruppen
Betriebsysteme: Windows 7; WindowsVista; WindowsXP; Linux; BS-Sonstige
Software: Textverarbeitung; Tabellenkalkulation; Datenbanken; Bildbearbeitung; Audio/mp3/Video; Security/Viren; E-Mail/Outlook; Internet Browser; SW-Sonstige
Hardware: Mainboard/CPU/RAM; Grafikkarten; Peripherie; HW Sonstiges
Netzwerk: DSL; W-Lan; Telekommunikation; NW-Sonstiges
Programmierung: Skripte(PHP,ASP,Perl...); Webseiten/HTML
Sonstiges: PC-Sonstiges; Plauderecke

Frage

Habe folgendes Problem. Da Excel nur 7 Ebenen zulässt komme ich nicht weiter. Hab in den Threads nachgelesen, kann das aber schlecht auf meine Formel übernehmen. Danke für Hilfe (Formel welche funktioniert) =WENN(UND(S15="L";AE15="Max")=WAHR;"Mod"; WENN(UND(S15="H";AE15="Max")=WAHR;"High"; WENN(UND(S15="L";AE15="Mod")=WAHR;"Low"; WENN(UND(S15="H";AE15="Mod")=WAHR;"Mod"; WENN(UND(S15="L";AE15="Min")=WAHR;"Min"; WENN(UND(S15="H";AE15="Min")=WAHR;"Low"; "")))))) nun wollte ich die Formel ergänzen indem ich folgende Argumente hinzufüge: =WENN(UND(S15="S";AE15="Max")=WAHR;"High"; WENN(UND(S15="S";AE15="Mod")=WAHR;"Mod"; WENN(UND(S15="S";AE15="Min")=WAHR;"Min"; doch leider, kommt mir eine Fehlermeldung, dass die Formel einen Fehler enthalte, doch ich finde keinen. Die Formel sieht von mir aus korrekt aus! Könnte mir vorstellen, dass zuviele verknüpfungen darin enthalten sein könnten.

Antwort 1 von Saarbauer

Hallo,

seh mal hier nach, im Prinzip das gleiche Problem

https://supportnet.de/threads/1390978

Gruß

Helmut

Antwort 2 von Tomschi

Vielleicht klappts damit:
=WENN(UND(S15="L";AE15="Max")=WAHR;"Mod";"")&WENN(UND(S15="H";AE15="Max")=WAHR;"High";"")&WENN(UND(S15="L";AE15="Mod")=WAHR;"Low";"")&...

Tom

Antwort 3 von Tomschi

Zu spät.
;-((

Antwort 4 von mike1982

Hallo Tomschi, deine Version bringt selbe Meldung. Aber danke werde dem nochmals nachgehen. Vielleicht ab ich einen Fehler gemacht.

=WENN(UND(S15="L";AE15="Max")=WAHR;"Mod";"")&WENN(UND(S15="H";AE15="Max")=WAHR;"High";"")&WENN(UND(S15="L";AE15="Mod")=WAHR;"Low";"")&WENN(UND(S15="H";AE15="Mod")=WAHR;"Mod";"")&WENN(UND(S15="L";AE15="Min")=WAHR;"Min";"")&WENN(UND(S15="H";AE15="Min")=WAHR;"Low";"")&WENN(UND(S15="S";AE15="Max")=WAHR;"High";"")&WENN(UND(S15="S";AE15="Mod")=WAHR;"Mod";"")&WENN(UND(S15="S";AE15="Min")=WAHR;"Min";"")))))))))

Antwort 5 von mike1982

so ist vielleicht übersichtlicher

=WENN(UND(S15="L";AE15="Max")=WAHR;"Mod";"")
&WENN(UND(S15="H";AE15="Max")=WAHR;"High";"")
&WENN(UND(S15="L";AE15="Mod")=WAHR;"Low";"")
&WENN(UND(S15="H";AE15="Mod")=WAHR;"Mod";"")
&WENN(UND(S15="L";AE15="Min")=WAHR;"Min";"")
&WENN(UND(S15="H";AE15="Min")=WAHR;"Low";"")
&WENN(UND(S15="S";AE15="Max")=WAHR;"High";"")
&WENN(UND(S15="S";AE15="Mod")=WAHR;"Mod";"")
&WENN(UND(S15="S";AE15="Min")=WAHR;"Min";"")))))))))

Antwort 6 von rapushnik

Jetzt hast du aber eine große Auswahl ;-)
gruß

entweder so:
=WENN(UND(S15="L";AE15="Max");"Mod";
WENN(ODER(UND(S15="H";AE15="Max");UND(S15="S";AE15="Max"));"High";
WENN(UND(S15="L";AE15="Mod");"Low";
WENN(ODER(UND(S15="H";AE15="Mod");UND(S15="S";AE15="Mod"));"Mod";
WENN(UND(S15="H";AE15="Min");"Low";
WENN(ODER(UND(S15="L";AE15="Min");UND(S15="S";AE15="Min"));"Min";
""))))))

oder kürzer, so:
=WENN(AE15="Max"; WENN(S15="L";"Mod"; WENN(ODER(S15="H";S15="S");"High";""));
WENN(AE15="Mod"; WENN(S15="L";"Low"; WENN(ODER(S15="H";S15="S");"Mod"; ""));
WENN(AE15="Min"; WENN(S15="H";"Low"; WENN(ODER(S15="L";S15="S");"Min"; ""));
"")))

Antwort 7 von mike1982

Ok danke , dass müsste gehn! Werds gleich probieren

Antwort 8 von rapushnik

die Formeln sehen hier irgendwie wüste aus ... wenn du es in ein Wordpad kopierst, siehst du die Logik und kannst es später erweitern.

@Tomschi: Das mit den & habe ich noch nicht gekannt. Sehr brauchbar!

gruß

Antwort 9 von mike1982

Hat funktioniert! Danke vielmal